reserve E,V for set, G,G1,G2 for _Graph, c,c1,c2 for Cardinal, n for Nat;
reserve f for VColoring of G;
reserve g for EColoring of G;
reserve t for TColoring of G;

theorem Th175:
  for v being object, G1 being addAdjVertexAll of G2,v,V
  st G2 is c-tcolorable holds G1 is (c+`1+`card V)-tcolorable
proof
  let v be object, G1 be addAdjVertexAll of G2,v,V;
  assume A1: G2 is c-tcolorable;
  per cases;
  suppose A2: not v in the_Vertices_of G2 & V c= the_Vertices_of G2;
    :: construct the coloring
    consider t0 being TColoring of G2 such that
      A3: t0 is proper & card((rng t0_V) \/ rng t0_E) c= c by A1;
    set R = (rng t0_V) \/ rng t0_E, E = G1.edgesBetween(V,{v});
    set h = <: E --> R, id E :>, g = t0_E +* h, f = t0_V +* (v .--> R);
    A4: dom h = E & rng t0_E c= R by Lm8, XBOOLE_1:7;
    then reconsider g as EColoring of G1 by A2, Th82;
    reconsider f as VColoring of G1 by A2, Th7;
    :: show it is proper
    reconsider g as proper EColoring of G1 by A2, A3, A4, Th96;
    reconsider t = [f,g] as TColoring of G1;
    not R in rng t0_V
    proof
      assume A5: R in rng t0_V;
      rng t0_V c= R by XBOOLE_1:7;
      then R in R by A5;
      hence contradiction;
    end;
    then A6: t_V is proper by A2, A3, Th25;
    now
      let e,u,w be object;
      assume A7: e Joins u,w,G1;
      per cases by A7, GLIB_006:72;
      suppose A8: not e in the_Edges_of G2;
        A9: the_Edges_of G1 = the_Edges_of G2 \/ E by A2, GLIB_007:59;
        e in the_Edges_of G1 by A7, GLIB_000:def 13;
        then A10: e in E by A8, A9, XBOOLE_0:def 3;
        then e SJoins V,{v},G1 by GLIB_000:def 30;
        then consider x being object such that
          A11: x in V & e Joins x,v,G1 by GLIB_000:102;
        A12: x <> v by A2, A11;
        e in dom h by A10, Lm8;
        then A13: t_E.e = h.e by FUNCT_4:13
          .= [R,e] by A10, Lm9;
        per cases by A7, A11, GLIB_000:15;
        suppose A14: u = x & w = v;
          then A15: t_V.u = t0_V.u by A12, FUNCT_4:83;
          u in the_Vertices_of G2 by A2, A11, A14;
          then u in dom t0_V by PARTFUN1:def 2;
          then A16: t0_V.u in rng t0_V by FUNCT_1:3;
          assume t_V.u = t_E.e;
          then A17: [R,e] in rng t0_V by A13, A15, A16;
          rng t0_V c= R by XBOOLE_1:7;
          then [R,e] in R by A17;
          then A18: {{R,e},{R}} in R by TARSKI:def 5;
          A19: R in {R} by TARSKI:def 1;
          {R} in {{R,e},{R}} by TARSKI:def 2;
          hence contradiction by A18, A19, XREGULAR:7;
        end;
        suppose u = v & w = x;
          then A20: t_V.u = R by FUNCT_4:113;
          assume t_V.u = t_E.e;
          then R = {{R,e},{R}} by A13, A20, TARSKI:def 5;
          then R in {R} & {R} in R by TARSKI:def 1, TARSKI:def 2;
          hence contradiction;
        end;
      end;
      suppose A21: e Joins u,w,G2;
        then A22: t0_V.u <> t0_E.e by A3, Th146;
        A23: e in the_Edges_of G2 & u in the_Vertices_of G2
          by A21, GLIB_000:def 13, GLIB_000:13;
        the_Edges_of G2 misses E by A2, GLIB_007:59;
        then not e in E by A23, XBOOLE_0:3;
        then not e in dom h by Lm8;
        then A24: t_E.e = t0_E.e by FUNCT_4:11;
        t_V.u = t0_V.u by A2, A23, FUNCT_4:83;
        hence t_V.u <> t_E.e by A22, A24;
      end;
    end;
    then A25: t is proper by A6, Th146;
    :: count the colors
    rng t0_V \/ rng(v.-->R) = rng t0_V \/ rng{[v,R]} by FUNCT_4:82
      .= rng t0_V \/ {R} by RELAT_1:9;
    then A26: rng f c= rng t0_V \/ {R} by FUNCT_4:17;
    A27: rng g c= rng t0_E \/ rng h by FUNCT_4:17;
    (rng t0_V \/ {R}) \/ (rng t0_E \/ rng h)
       = (rng t0_V \/ {R} \/ rng t0_E) \/ rng h by XBOOLE_1:4
      .= R \/ {R} \/ rng h by XBOOLE_1:4;
    then rng f \/ rng g c= R \/ {R} \/ rng h by A26, A27, XBOOLE_1:13;
    then A28: card(rng f \/ rng g) c= card(R \/ {R} \/ rng h) by CARD_1:11;
    not R in R;
    then A29: R misses {R} by ZFMISC_1:50;
    A30: card E = card V
    proof
      consider E0 being set such that
        A31: card V = card E0 & E0 misses the_Edges_of G2 and
        A32: the_Edges_of G1 = the_Edges_of G2 \/ E0 and
        for v1 being object st v1 in V ex e1 being object st e1 in E0 &
          e1 Joins v1,v,G1 &
          for e2 being object st e2 Joins v1,v,G1 holds e1 = e2
          by A2, GLIB_007:def 4;
      thus thesis by A2, A31, A32, GLIB_007:58;
    end;
    card(R \/ {R} \/ rng h)
       = card(R \/ {R}) +` card rng h by Lm21, CARD_2:35
      .= card R +` card {R} +` card rng h by A29, CARD_2:35
      .= card R +` 1 +` card rng h by CARD_1:30
      .= card R +` 1 +` card [: {R}, E :] by Lm10
      .= card R +` 1 +` card [: E, {R} :] by CARD_2:4
      .= card R +` 1 +` card E by CARD_1:69
      .= card R +` (1 +` card V) by A30, CARD_2:19;
    then card(R \/ {R} \/ rng h) c= c +` (1 +` card V) by A3, CARD_2:84;
    then card(R \/ {R} \/ rng h) c= c +` 1 +` card V by CARD_2:19;
    hence thesis by A25, A28, XBOOLE_1:1;
  end;
  suppose not(not v in the_Vertices_of G2 & V c= the_Vertices_of G2);
    then G1 == G2 by GLIB_007:def 4;
    then G1 is c-tcolorable by A1, Th167;
    then G1 is (c+`1)-tcolorable by Th161, CARD_2:94;
    hence thesis by Th161, CARD_2:94;
  end;
end;
