reserve i,j for Nat;

theorem Th17:
 for C being initialized standardized ConstructorSignature
 for e being expression of C
  st (e.{})`1 in Vars
 ex x being Element of Vars st x = (e.{})`1 & e = x-term C
  proof let C be initialized standardized ConstructorSignature;
   let t be expression of C such that
A1: (t.{})`1 in Vars;
   set X = MSVars C;
   set V = X (\/) ((the carrier of C) --> {0});
   reconsider q = t as Term of C, V by MSAFREE3:8;
   per cases by MSATERM:2;
   suppose q.{} in [:the carrier' of C, {the carrier of C}:]; then
     (q.{})`1 in the carrier' of C &
     the carrier' of C misses Vars by Th10,MCART_1:10;
    hence thesis by A1,XBOOLE_0:3;
   end;
   suppose
     ex s being SortSymbol of C, v being Element of V.s st q.{} = [v,s]; then
    consider s being SortSymbol of C, v being Element of V.s such that
A2:  t.{} = [v,s];
A3:  q = root-tree [v,s] by A2,MSATERM:5;
    reconsider x = v as Element of Vars by A1,A2;
    take x;
     the carrier of C = {a_Type, an_Adj, a_Term} by ABCMIZ_1:def 9; then
A4:  s = a_Term or s = a_Type or s = an_Adj by ENUMSET1:def 1;
     ((the carrier of C) --> {0}).s = {0}; then
     V.s = X.s \/ {0} by PBOOLE:def 4; then
A5:  s = a_Term or V.s = {} \/ {0} by A4,ABCMIZ_1:def 25;
     v in V.s & x <> 0;
    hence thesis by A2,A3,A5;
   end;
  end;
