reserve x for set,
  D for non empty set,
  k, n for Nat,
  z for Nat;
reserve
  N for with_zero set,
  S for IC-Ins-separated non empty
          with_non-empty_values AMI-Struct over N,
  i for Element of the InstructionsF of S,
  l, l1, l2, l3 for Nat,
  s for State of S;
reserve ss for Element of product the_Values_of S;
reserve T for standard IC-Ins-separated non empty
     with_non-empty_values AMI-Struct over N;

theorem
  for i being Instruction of Trivial-AMI(N) holds i is halting
proof
  let i be Instruction of Trivial-AMI(N);
  set M = Trivial-AMI(N);
A1: the InstructionsF of M = {[0,{},{}]} by EXTPRO_1:def 1;
  let s be State of M;
  reconsider s as Element of product the_Values_of M by CARD_3:107;
A2:  the Object-Kind of M = 0 .--> 0 &
  the ValuesF of M = N --> NAT by EXTPRO_1:def 1;
  (the Execution of M).i = ([0,{},{}] .--> id product the_Values_of M).i
         by A2,EXTPRO_1:def 1
    .= id product the_Values_of M by A1;
  then (the Execution of M).i.s = s;
  hence thesis;
end;
