reserve D,D1,D2 for non empty set,
        d,d1,d2 for XFinSequence of D,
        n,k,i,j for Nat;
reserve A,B for object,
        v for Element of (n+k)-tuples_on {A,B},
        f,g for FinSequence;

theorem Th16:
  f is A,n,B,k-dominated-election & i < n-k
    implies f^(i|->B) is A,n,B,k+i-dominated-election
proof
  set iB=i|->B;
  assume that
A1:   f is A,n,B,k-dominated-election
    and
A2:   i < n-k;
A3:A<>B by A1,Th13;
A4:rng iB c= {B} by FUNCOP_1:13;
   {B} c= {A,B} by ZFMISC_1:7;
   then rng iB c= {A,B} by A4;
   then reconsider iB as FinSequence of {A,B} by FINSEQ_1:def 4;
   reconsider F=f as Element of (n+k)-tuples_on {A,B} by A1;
   set fB=f^(i|->B);
A5:len f = n+k by A1,CARD_1:def 7;
A6:len (F^iB) = n+k+i by CARD_1:def 7;
   then reconsider FB=F^iB as Element of (n+(k+i))-tuples_on {A,B}
     by FINSEQ_2:92;
A7:not B in {A} by A3,TARSKI:def 1;
   then
A8:iB"{A} = {} by FUNCOP_1:16;
A9:card (FB"{A}) = card (F"{A})+card (iB"{A}) by FINSEQ_3:57;
A10:card (F"{A}) = n by Def1,A1;
   hence fB in Election(A,n,B,k+i) by A9,A8,Def1;
   let j such that
A11: j>0;
   set FBj=FB|j;
A12:card (f"{B}) = k by A3,Th11,A1;
A13:i+k < n-k+k by A2,XREAL_1:6;
   per cases;
     suppose j <= n+k;
       then FBj = f|j by A5,FINSEQ_5:22;
       hence card ((fB|j)"{A}) > card ((fB|j)"{B}) by A11,A1;
     end;
     suppose
A14:     j > n+k & j <= n+k+i;
       then reconsider j1=j-(n+k) as Nat by NAT_1:21;
A15:   j1+(n+k)<= i+(n+k) by A14;
       then
A16:   j1 <=i by XREAL_1:6;
       Seg i/\Seg j1=Seg j1 by A15,XREAL_1:6,FINSEQ_1:7;
       then
A17:   iB|Seg j1 = Seg j1 --> B by FUNCOP_1:12;
A18:   (Seg j1 --> B) "{A} = {} by A7,FUNCOP_1:16;
A19:   FBj = FB| Seg (len F +j1) by A5
          .= F^(Seg j1 --> B) by A17,FINSEQ_6:14;
       then
A20:   card (FBj"{A}) = n + card ((Seg j1 --> B) "{A}) by A10,FINSEQ_3:57
                     .= n by A18;
       B in {B} by TARSKI:def 1;
       then (Seg j1 --> B) "{B} = Seg j1 by FUNCOP_1:14;
       then card (FBj"{B}) = k + card Seg j1 by A12,A19,FINSEQ_3:57
                          .= k+ j1 by FINSEQ_1:57;
       then card (FBj"{B}) <= k+ i by A16,XREAL_1:6;
       hence card ((fB|j)"{A}) > card ((fB|j)"{B}) by A20,A13,XXREAL_0:2;
     end;
     suppose j > n+k+i;
       then
A21:   FB|j=FB by FINSEQ_1:58,A6;
A22:   iB "{A} = {} by A7,FUNCOP_1:16;
       B in {B} by TARSKI:def 1;
       then iB "{B} = Seg i by FUNCOP_1:14;
       then card (FB"{B}) = k+card Seg i by A12,FINSEQ_3:57
                         .= k+i by FINSEQ_1:57;
       hence card ((fB|j)"{A}) > card ((fB|j)"{B}) by A21,A22,A9,Def1,A1,A13;
     end;
end;
