
theorem
  for X, Y being compact non empty TopSpace, R being Subset-Family of X
st R = { Q where Q is open Subset of X : [:[#]Y, Q:] c= union Base-Appr [#][:Y,
  X:] } holds R is open & R is Cover of [#]X
proof
  let X, Y be compact non empty TopSpace, R be Subset-Family of X;
  assume
A1: R = { Q where Q is open Subset of X : [:[#]Y, Q:] c= union Base-Appr
  [#][:Y, X:] };
  now
    let P be Subset of X;
    assume P in R;
    then ex E being open Subset of X st E = P & [:[#]Y, E:] c= union Base-Appr
    [#][:Y, X:] by A1;
    hence P is open;
  end;
  hence R is open;
  [#]X c= union R
  proof
    let k be object;
    assume k in [#]X;
    then reconsider k9 = k as Point of X;
    reconsider Z = [:[#]Y, {k9}:] as Subset of [:Y, X:];
    Z c= [#][:Y, X:];
    then Z c= union Base-Appr [#][:Y, X:] by BORSUK_1:13;
    then
A2: Base-Appr [#][:Y, X:] is Cover of Z by SETFAM_1:def 11;
    Z is compact by Th16;
    then consider G being Subset-Family of [:Y, X:] such that
A3: G c= Base-Appr [#][:Y, X:] and
A4: G is Cover of Z and
    G is finite by A2;
    set uR = union G;
    set Q = { x where x is Point of X : [:[#]Y, {x}:] c= uR };
    Q c= the carrier of X
    proof
      let k be object;
      assume k in Q;
      then ex x1 being Point of X st k = x1 & [:[#]Y, {x1}:] c= uR;
      hence thesis;
    end;
    then reconsider Q as Subset of X;
    Z c= union G by A4,SETFAM_1:def 11;
    then
A5: k9 in Q;
A6: [:[#]Y, Q:] c= union Base-Appr [#][:Y, X:]
    proof
      let z be object;
      assume z in [:[#]Y, Q:];
      then consider x1, x2 be object such that
A7:   x1 in [#]Y and
A8:   x2 in Q and
A9:  z = [x1, x2] by ZFMISC_1:def 2;
      consider x29 being Point of X such that
A10:  x29 = x2 and
A11:  [:[#]Y, {x29}:] c= uR by A8;
      x2 in {x29} by A10,TARSKI:def 1;
      then
A12:  z in [:[#]Y, {x29}:] by A7,A9,ZFMISC_1:87;
      uR c= union Base-Appr [#][:Y, X:] by A3,ZFMISC_1:77;
      then [:[#]Y, {x29}:] c= union Base-Appr [#][:Y, X:] by A11;
      hence thesis by A12;
    end;
    uR is open by A3,TOPS_2:11,19;
    then Q in the topology of X by Th12;
    then Q is open by PRE_TOPC:def 2;
    then Q in R by A1,A6;
    hence thesis by A5,TARSKI:def 4;
  end;
  hence thesis by SETFAM_1:def 11;
end;
