reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem Th17:
  for h being Function,A9,B9,C9,D9 being object st G={A,B,C,D} & h =
(B .--> B9) +* (C .--> C9) +* (D .--> D9) +* (A .--> A9) holds rng h = {h.A,h.B
  ,h.C,h.D}
proof
  let h be Function;
  let A9,B9,C9,D9 be object;
  assume that
A1: G={A,B,C,D} and
A2: h = (B .--> B9)+*(C .--> C9)+*(D .--> D9)+*(A .--> A9);
A3: dom h = G by A1,A2,Th16;
  then
A4: B in dom h by A1,ENUMSET1:def 2;
A5: rng h c= {h.A,h.B,h.C,h.D}
  proof
    let t be object;
    assume t in rng h;
    then consider x1 being object such that
A6: x1 in dom h and
A7: t = h.x1 by FUNCT_1:def 3;
    now
      per cases by A1,A3,A6,ENUMSET1:def 2;
      case
        x1=A;
        hence thesis by A7,ENUMSET1:def 2;
      end;
      case
        x1=B;
        hence thesis by A7,ENUMSET1:def 2;
      end;
      case
        x1=C;
        hence thesis by A7,ENUMSET1:def 2;
      end;
      case
        x1=D;
        hence thesis by A7,ENUMSET1:def 2;
      end;
    end;
    hence thesis;
  end;
A8: D in dom h by A1,A3,ENUMSET1:def 2;
A9: C in dom h by A1,A3,ENUMSET1:def 2;
A10: A in dom h by A1,A3,ENUMSET1:def 2;
  {h.A,h.B,h.C,h.D} c= rng h
  proof
    let t be object;
    assume
A11: t in {h.A,h.B,h.C,h.D};
    per cases by A11,ENUMSET1:def 2;
    suppose
      t=h.A;
      hence thesis by A10,FUNCT_1:def 3;
    end;
    suppose
      t=h.B;
      hence thesis by A4,FUNCT_1:def 3;
    end;
    suppose
      t=h.C;
      hence thesis by A9,FUNCT_1:def 3;
    end;
    suppose
      t=h.D;
      hence thesis by A8,FUNCT_1:def 3;
    end;
  end;
  hence thesis by A5,XBOOLE_0:def 10;
end;
