reserve Y for non empty set;
reserve B for Subset of Y;

theorem
  for a,b being Function of Y,BOOLEAN holds (a 'eqv' b)=I_el(Y) iff a = b
proof
  let a,b be Function of Y,BOOLEAN;
A1: for a,b being Function of Y,BOOLEAN holds (a 'eqv' b)=I_el(Y)
  implies a = b
  proof
    let a,b be Function of Y,BOOLEAN;
    assume
A2: (a 'eqv' b)=I_el(Y);
A3: for x being Element of Y holds ('not' a.x '&' b.x) 'or' (a.x '&' 'not'
    b.x) = FALSE
    proof
      let x be Element of Y;
      (a 'eqv' b).x = 'not' (a.x 'xor' b.x) by Def9;
      then 'not' (a.x 'xor' b.x) = TRUE by A2,Def11;
      hence thesis;
    end;
A4: for x being Element of Y holds ('not' a.x '&' b.x) = FALSE & (a.x '&'
    'not' b.x) = FALSE
    proof
      let x be Element of Y;
A5:   (a.x '&' 'not' b.x) = TRUE or (a.x '&' 'not' b.x) = FALSE by
XBOOLEAN:def 3;
      ('not' a.x '&' b.x) 'or' (a.x '&' 'not' b.x) = FALSE by A3;
      hence thesis by A5;
    end;
      let x be Element of Y;
      ('not' a.x '&' b.x) = FALSE by A4;
      then
A6:  'not' a.x = TRUE & b.x = FALSE or 'not' a.x = FALSE & b.x = FALSE
      or 'not' a.x = FALSE & b.x = TRUE by MARGREL1:12,XBOOLEAN:def 3;
      (a.x '&' 'not' b.x) = FALSE by A4;
      hence thesis by A6;
  end;
  for a,b being Function of Y,BOOLEAN holds a = b implies (a 'eqv'
  b)=I_el(Y)
  proof
    let a,b be Function of Y,BOOLEAN;
    assume
A7: a = b;
A8: for x being Element of Y holds ('not' a.x '&' b.x) = FALSE & (a.x '&'
    'not' b.x) = FALSE
    proof
      let x be Element of Y;
      b.x = TRUE iff 'not' b.x = FALSE;
      then
      a.x = FALSE & 'not' b.x = TRUE or a.x = TRUE & 'not' b.x = FALSE by A7,
XBOOLEAN:def 3;
      hence thesis;
    end;
      let x be Element of Y;
      (a.x '&' 'not' b.x) = FALSE by A8;
      then 'not' (a.x 'xor' b.x) = TRUE by A8;
      then (a 'eqv' b).x= TRUE by Def9;
      hence thesis by Def11;
  end;
  hence thesis by A1;
end;
