reserve Y for non empty set;

theorem
  for a,b,c being Function of Y,BOOLEAN holds (a 'imp' b)=I_el(Y)
  implies (a '&' c) 'imp' (b '&' c)=I_el(Y)
proof
  let a,b,c be Function of Y,BOOLEAN;
  assume
A1: (a 'imp' b)=I_el(Y);
  for x being Element of Y holds ((a '&' c) 'imp' (b '&' c)).x=TRUE
  proof
    let x be Element of Y;
    (a 'imp' b).x= TRUE by A1,BVFUNC_1:def 11;
    then
A2: 'not' a.x 'or' b.x = TRUE by BVFUNC_1:def 8;
    ((a '&' c) 'imp' (b '&' c)).x ='not' (a '&' c).x 'or' (b '&' c).x by
BVFUNC_1:def 8
      .='not'( a.x '&' c.x) 'or' (b '&' c).x by MARGREL1:def 20
      .=('not' a.x 'or' 'not' c.x) 'or' (b.x '&' c.x) by
MARGREL1:def 20
      .=(('not' c.x 'or' 'not' a.x) 'or' b.x) '&' (('not' a.x 'or'
    'not' c.x) 'or' c.x) by XBOOLEAN:9
      .=('not' c.x 'or' ('not' a.x 'or' b.x)) '&' ('not' a.x 'or' (
    'not' c.x 'or' c.x))
      .=('not' c.x 'or' ('not' a.x 'or' b.x)) '&' ('not' a.x 'or'
    TRUE) by XBOOLEAN:102
      .=TRUE by A2;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
