reserve X,x,y,z for set;
reserve n,m,k,k9,d9 for Nat;
reserve d for non zero Nat;
reserve i,i0,i1 for Element of Seg d;
reserve l,r,l9,r9,l99,r99,x,x9,l1,r1,l2,r2 for Element of REAL d;
reserve Gi for non trivial finite Subset of REAL;
reserve li,ri,li9,ri9,xi,xi9 for Real;
reserve G for Grating of d;

theorem
  Gi = {li,ri} implies
  ([li9,ri9] is Gap of Gi iff li9 = li & ri9 = ri or li9 = ri & ri9 = li)
proof
  assume
A1: Gi = {li,ri};
  hereby
    assume
A2: [li9,ri9] is Gap of Gi;
    then
A3: li9 in Gi by Th13;
A4: ri9 in Gi by A2,Th13;
A5: li9 = li or li9 = ri by A1,A3,TARSKI:def 2;
    li9 <> ri9 by A2,Th13;
    hence li9 = li & ri9 = ri or li9 = ri & ri9 = li by A1,A4,A5,TARSKI:def 2;
  end;
  assume
A6: li9 = li & ri9 = ri or li9 = ri & ri9 = li;
    li9 in REAL & ri9 in REAL by XREAL_0:def 1;
    then [li9,ri9] in [:REAL,REAL:] by ZFMISC_1:87;
    then reconsider liri = [li9,ri9] as Element of [:REAL,REAL:];
  liri is Gap of Gi
  proof
   take li9,ri9;
    li <> ri by A1,Th3;
   hence thesis by A1,TARSKI:def 2,XXREAL_0:1,A6;
  end;
  hence thesis;
end;
