reserve GX for TopSpace;
reserve A, B, C for Subset of GX;
reserve TS for TopStruct;
reserve K, K1, L, L1 for Subset of TS;

theorem Th17:
  A is connected & B is connected & not A,B are_separated implies
  A \/ B is connected
proof
  assume that
A1: A is connected and
A2: B is connected and
A3: not A,B are_separated;
  assume not A \/ B is connected;
  then consider P,Q being Subset of GX such that
A4: A \/ B = P \/ Q and
A5: P,Q are_separated and
A6: P <> {}GX and
A7: Q <> {}GX by Th15;
A8: not(A c= Q & B c= P) by A3,A5,Th7;
  P misses Q by A5,Th1;
  then
A9: P /\ Q = {};
A10: now
A11: P c= P \/ Q by XBOOLE_1:7;
    assume that
A12: A c= P and
A13: B c= P;
    A \/ B c= P by A12,A13,XBOOLE_1:8;
    then P \/ Q = P by A4,A11;
    hence contradiction by A7,A9,XBOOLE_1:7,28;
  end;
A14: now
A15: Q c= Q \/ P by XBOOLE_1:7;
    assume that
A16: A c= Q and
A17: B c= Q;
    A \/ B c= Q by A16,A17,XBOOLE_1:8;
    then Q \/ P = Q by A4,A15;
    hence contradiction by A6,A9,XBOOLE_1:7,28;
  end;
  not(A c= P & B c= Q) by A3,A5,Th7;
  hence contradiction by A1,A2,A4,A5,A10,A8,A14,Th16,XBOOLE_1:7;
end;
