reserve MS for OrtAfPl;
reserve MP for OrtAfSp;
reserve V for RealLinearSpace;
reserve w,y,u,v for VECTOR of V;

theorem
  for o,c,c1,a being Element of MS st not LIN o,c,a ex a1 being Element
  of MS st o,a _|_ o,a1 & c,a _|_ c1,a1
proof
  let o,c,c1,a be Element of MS such that
A1: not LIN o,c,a;
  set X=Line(c,a),Y=Line(o,a);
  c <>a by A1,Th1;
  then
A2: X is being_line by ANALMETR:def 12;
  then consider X9 being Subset of MS such that
A3: c1 in X9 and
A4: X _|_ X9 by CONMETR:3;
  o<>a by A1,Th1;
  then Y is being_line by ANALMETR:def 12;
  then consider Y9 being Subset of MS such that
A5: o in Y9 and
A6: Y _|_ Y9 by CONMETR:3;
  reconsider X1=X9,Y1=Y9 as Subset of the AffinStruct of MS;
  Y9 is being_line by A6,ANALMETR:44;
  then
A7: Y1 is being_line by ANALMETR:43;
  reconsider o9=o,c9=c,a9=a as Element of the AffinStruct of MS;
A8: X=Line(c9,a9) by ANALMETR:41;
  then
A9: a in X by AFF_1:15;
  Y=Line(o9,a9) by ANALMETR:41;
  then
A10: o in Y & a in Y by AFF_1:15;
A11: c in X by A8,AFF_1:15;
  not X9 // Y9
  proof
    reconsider X1=X,Y1=Y as Subset of the carrier of the AffinStruct of MS;
    assume not thesis;
    then X9 _|_ Y by A6,ANALMETR:52;
    then X // Y by A4,ANALMETR:65;
    then X1 // Y1 by ANALMETR:46;
    then
A12: o in X by A9,A10,AFF_1:45;
    a in X by A8,AFF_1:15;
    hence contradiction by A1,A2,A11,A12,CONMETR:4;
  end;
  then
A13: not X1 // Y1 by ANALMETR:46;
  X9 is being_line by A4,ANALMETR:44;
  then X1 is being_line by ANALMETR:43;
  then consider a19 being Element of the AffinStruct of MS such that
A14: a19 in X1 & a19 in Y1 by A7,A13,AFF_1:58;
  reconsider a1=a19 as Element of MS;
  take a1;
  thus thesis by A3,A4,A5,A6,A11,A9,A10,A14,ANALMETR:56;
end;
