reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (exp_R*cot) implies exp_R*cot is_differentiable_on Z & for x
  st x in Z holds ((exp_R*cot)`|Z).x = -exp_R.(cot.x)/(sin.x)^2
proof
  assume
A1: Z c= dom (exp_R*cot);
A2: for x st x in Z holds sin.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom (cos/sin) by A1,FUNCT_1:11;
    hence thesis by Th2;
  end;
A3: for x st x in Z holds exp_R*cot is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.x<>0 by A2;
    then
A4: cot is_differentiable_in x by FDIFF_7:47;
    exp_R is_differentiable_in cot.x by SIN_COS:65;
    hence thesis by A4,FDIFF_2:13;
  end;
  then
A5: exp_R*cot is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((exp_R*cot)`|Z).x = -exp_R.(cot.x)/(sin.x)^2
  proof
    let x;
A6: exp_R is_differentiable_in cot.x by SIN_COS:65;
    assume
A7: x in Z;
    then
A8: sin.x<>0 by A2;
    then cot is_differentiable_in x by FDIFF_7:47;
    then diff(exp_R*cot,x) = diff(exp_R,cot.x)*diff(cot,x) by A6,FDIFF_2:13
      .=diff(exp_R,cot.x)*(-1/(sin.x)^2) by A8,FDIFF_7:47
      .=exp_R.(cot.x) * (-1/(sin.x)^2) by SIN_COS:65
      .=-exp_R.(cot.x)/(sin.x)^2;
    hence thesis by A5,A7,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
