
theorem eval1:
for R,S being non degenerated comRing
for n being Ordinal
for x being Function of n,S
st R is Subring of S holds Ext_eval(1_(n,R),x) = 1.S
proof
  let A,B be non degenerated comRing; let n be Ordinal;
  let x be Function of n,B;
  set p = 1_(n,A);
    assume
A0: A is Subring of B;
    field(BagOrder n) = Bags n by ORDERS_1:12; then
B0: BagOrder n linearly_orders (Support p) by ORDERS_1:37,ORDERS_1:38;
C:  p = 1.Polynom-Ring(n,A) &
    0_(n,A) = 0.Polynom-Ring(n,A) by POLYNOM1:def 11;
    consider y being FinSequence of B such that
A1: Ext_eval(p,x) = Sum y & len y = len SgmX(BagOrder n, Support p) &
    for i being Element of NAT st 1 <= i & i <= len y
    holds y.i = In( (p * SgmX(BagOrder n, Support p)).i, B) *
                eval(((SgmX(BagOrder n, Support p))/.i),x) by defeval;
B1: Support p = { EmptyBag n } by C,POLYNOM7:14; then
A2: card(Support p) = 1 by CARD_1:30; then
A3: len y = 1 by A1,B0,PRE_POLY:11;
    rng SgmX(BagOrder n, Support p) = {EmptyBag n} by B0,B1,PRE_POLY:def 2;
    then
A5: SgmX(BagOrder n, Support p) = <* EmptyBag n *>
    by A2,B0,PRE_POLY:11,FINSEQ_1:39; then
J:  dom SgmX(BagOrder n, Support p) = Seg 1 by FINSEQ_1:38;
B2: SgmX(BagOrder n, Support p)/.1
        = SgmX(BagOrder n, Support p).1 by J,PARTFUN1:def 6,FINSEQ_1:3
       .= EmptyBag n by A5;
I:  1.B = 1.A by A0,C0SP1:def 3;
B3: (p * SgmX(BagOrder n, Support p)).1
       = p.(SgmX(BagOrder n, Support p).1) by J,FUNCT_1:13,FINSEQ_1:3
      .= p.(EmptyBag n) by B2,J,PARTFUN1:def 6,FINSEQ_1:3
      .= 1.A by POLYNOM1:25;
A4: y.1 = In( (p * SgmX(BagOrder n, Support p)).1, B) *
          eval(((SgmX(BagOrder n, Support p))/.1),x) by A1,A3
       .= 1.B by I,B3,B2,POLYNOM2:14;
  Sum y = Sum <*1.B*> by A2,A4,A1,B0,PRE_POLY:11,FINSEQ_1:40
       .= 1.B by RLVECT_1:44;
  hence thesis by A1;
end;
