 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;
reserve n for non zero Nat;

theorem
   for x being non trivial Element of F, o being object st not o in [#]F
   holds isoR(x,o) is one-to-one
   proof
     let x be non trivial Element of F;
     let o be object;
     assume not o in [#]F; then
A1:  a <> o;
     set f = isoR(x,o);
     now let x1,x2 be object;
       assume
A2:    x1 in dom f & x2 in dom f & f.x1 = f.x2;
       per cases;
         suppose
A3:        x1 = x;
           now assume
A4:          x2 <> x;
             reconsider a = x2 as Element of F by A2;
             a = f.a by A4,Def9 .= o by A3,A2,Def9;
             hence contradiction by A1;
           end;
           hence x1 = x2 by A3;
         end;
         suppose
A5:        x1 <> x;
           reconsider a = x1 as Element of F by A2;
A6:        f.a = a by A5,Def9;
           now assume
A7:          x2 <> x1;
             per cases;
               suppose x2 = x;
                 hence contradiction by A6,A1,A2,Def9;
               end;
               suppose
A8:              x2 <> x;
                 reconsider b = x2 as Element of F by A2;
                 thus contradiction by A2,A6,A8,A7,Def9;
               end;
             end;
             hence x1 = x2;
           end;
         end;
         hence f is one-to-one;
       end;
