reserve Omega for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S for non empty Subset of REAL;
reserve r for Real;
reserve T for Nat;
reserve I for TheEvent of r;

theorem Th600:
  Intersection ext_right_closed_sets(0) = {-infty}
proof
 for c being object holds c in Intersection ext_right_closed_sets(0) iff
  c in {-infty}
 proof
  let c be object;
  thus c in Intersection ext_right_closed_sets(0) implies c in {-infty}
proof
 assume
Y: c in Intersection ext_right_closed_sets(0);
 assume not c in {-infty};
 then WW: c <> -infty by TARSKI:def 1;
 reconsider c as Element of ExtREAL by Y;
 per cases by XXREAL_0:14,WW;
  suppose c = +infty; then
   not c in [.-infty,0-0.] by XXREAL_1:1; then
   not c in (ext_right_closed_sets(0)).(0+0) by Def3000;
  hence thesis by Y,PROB_1:13;
  end;
  suppose c in REAL;
   then reconsider c as Element of REAL;
   per cases;
   suppose c >= 0; then
    not c in [.-infty,0-(0+1).] by XXREAL_1:1; then
    not c in (ext_right_closed_sets(0)).(0+1) by Def3000;
    hence thesis by Y,PROB_1:13;
   end;
   suppose S1: c < 0;
    set finerg=[\ ((-1)*c)+1 /];
 WQ: finerg > 0
     proof
      ((-1)*c)+1-1>0 by S1;
      hence thesis by INT_1:def 6;
     end;
    finerg is Nat
    proof
     finerg in INT by INT_1:def 2;
     then consider k being Nat such that
 ZZ: finerg = k or finerg = -k by INT_1:def 1;
     thus thesis by ZZ,WQ;
    end;
    then reconsider finerg as Nat;
    not c in (ext_right_closed_sets(0)).(finerg+1)
    proof
z0:  (((-1)*c)+1)-1 < finerg by INT_1:def 6;
     finerg < finerg+1 by XREAL_1:29;
     then (((-1)*c)+0)<(finerg+1) by z0,XXREAL_0:2;
     then -(((-1)*c)+0) > -(finerg+1) by XREAL_1:24; then
     not c in [.-infty,0 - (finerg+1).] by XXREAL_1:1;
     hence thesis by Def3000;
    end;
   hence thesis by Y,PROB_1:13;
   end;
  end;
end;
   assume A12: c in {-infty};
   for n being Nat holds c in (ext_right_closed_sets(0)).n
   proof
    let n be Nat;
s2:  (ext_right_closed_sets(0)).n=[.-infty,0-n.] by Def3000;
     [.-infty,0-n.] = {-infty} \/ ].-infty,0-n.] by XXREAL_1:421; then
     {-infty} c= [.-infty,0-n.] by XBOOLE_1:7;
     hence thesis by A12,s2;
   end;
  hence thesis by PROB_1:13;
  end;
  hence thesis;
end;
