reserve p,p1,p2,q for Point of TOP-REAL 2,
  f,f1,f2,g,g1,g2 for FinSequence of TOP-REAL 2,
  r,s for Real,

  n,m,i,j,k for Nat,
  G for Go-board,
  x for set;
reserve f for non empty FinSequence of TOP-REAL 2;

theorem
  n in dom f & (for m st m in dom f holds (Y_axis(f)).n <= (Y_axis(f)).m
  ) implies f/.n in rng Col(GoB(f),1)
proof
  set x = X_axis(f), y = Y_axis(f), r = y.n;
  assume that
A1: n in dom f and
A2: for m st m in dom f holds r <= y.m;
  reconsider p=f/.n as Point of TOP-REAL 2;
A3: dom f = Seg len f by FINSEQ_1:def 3;
A4: dom y = Seg len y & len y = len f by FINSEQ_1:def 3,GOBOARD1:def 2;
  then
A5: y.n=p`2 by A1,A3,GOBOARD1:def 2;
A6: rng Incr(y) = rng y by SEQ_4:def 21;
  y.n in rng y by A1,A3,A4,FUNCT_1:def 3;
  then consider j being Nat such that
A7: j in dom Incr(y) and
A8: Incr(y).j=p`2 by A5,A6,FINSEQ_2:10;
  reconsider j as Element of NAT by ORDINAL1:def 12;
A9: 1<=j by A7,FINSEQ_3:25;
  then reconsider j1=j-1 as Element of NAT by INT_1:5;
A10: j<=len Incr(y) by A7,FINSEQ_3:25;
A11: now
    reconsider s=Incr(y).j1 as Real;
    assume j <> 1;
    then 1<j by A9,XXREAL_0:1;
    then 1+1<=j by NAT_1:13;
    then
A12: 1<=j1 by XREAL_1:19;
    j1<=j by XREAL_1:44;
    then j1<=len Incr(y) by A10,XXREAL_0:2;
    then
A13: j1 in dom Incr(y) by A12,FINSEQ_3:25;
    then Incr(y).j1 in rng Incr(y) by FUNCT_1:def 3;
    then
A14: ex m being Nat st m in dom y & y.m=s by A6,FINSEQ_2:10;
    j1<j by XREAL_1:44;
    then s<r by A5,A7,A8,A13,SEQM_3:def 1;
    hence contradiction by A2,A3,A4,A14;
  end;
A15: rng Incr(x) = rng x by SEQ_4:def 21;
  dom x = Seg len x & len x = len f by FINSEQ_1:def 3,GOBOARD1:def 1;
  then x.n=p`1 & x.n in rng x by A1,A3,FUNCT_1:def 3,GOBOARD1:def 1;
  then consider i being Nat such that
A16: i in dom Incr(x) and
A17: Incr(x).i=p`1 by A15,FINSEQ_2:10;
A18: p=|[p`1,p`2]| by EUCLID:53;
  len Col(GoB(f),1) = len GoB(f) by MATRIX_0:def 8;
  then
A19: dom Col(GoB(f),1) = dom GoB(f) by FINSEQ_3:29;
  len GoB(f)=card rng x & len Incr(x) = card rng x by Th13,SEQ_4:def 21;
  then
A20: dom Incr(x) = dom GoB(f) by FINSEQ_3:29;
  width GoB(f) = card rng y & len Incr(y) = card rng y by Th13,SEQ_4:def 21;
  then Indices GoB(f) = [:dom GoB(f), Seg width GoB(f):] & dom Incr(y) = Seg
  width GoB(f) by FINSEQ_1:def 3,MATRIX_0:def 4;
  then [i,1] in Indices GoB(f) by A16,A7,A20,A11,ZFMISC_1:87;
  then GoB(f)*(i,1) = |[p`1,p`2]| by A17,A8,A11,Def1;
  then (Col(GoB(f),1)).i = f/.n by A16,A20,A18,MATRIX_0:def 8;
  hence thesis by A16,A20,A19,FUNCT_1:def 3;
end;
