reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th17:
  1 <= j & j < width G implies Int h_strip(G,j) = { |[r,s]| : G*(1
  ,j)`2 < s & s < G*(1,j+1)`2 }
proof
  0 <> len G by MATRIX_0:def 10;
  then
A1: 1 <= len G by NAT_1:14;
  assume 1 <= j & j < width G;
  then
A2: h_strip(G,j) = { |[r,s]| : G*(1,j)`2 <= s & s <= G*(1,j+1)`2 } by A1,
GOBOARD5:5;
  thus Int h_strip(G,j) c= { |[r,s]| : G*(1,j)`2 < s & s < G*(1,j+1)`2 }
  proof
    let x be object;
    assume
A3: x in Int h_strip(G,j);
    then reconsider u = x as Point of Euclid 2 by Lm6;
    consider s1 being Real such that
A4: s1 > 0 and
A5: Ball(u,s1) c= h_strip(G,j) by A3,Th5;
    reconsider p = u as Point of TOP-REAL 2 by Lm6;
A6: p = |[p`1,p`2]| by EUCLID:53;
    set q2 = |[p`1+0,p`2-s1/2]|;
A7: s1/2 < s1 by A4,XREAL_1:216;
    then q2 in Ball(u,s1) by A4,A6,Th10;
    then q2 in h_strip(G,j) by A5;
    then ex r2,s2 st q2 = |[r2,s2]| & G*(1,j)`2 <= s2 & s2 <= G*(1,j+1)`2 by A2
;
    then G*(1,j)`2 <= p`2-s1/2 by SPPOL_2:1;
    then
A8: G*(1,j)`2+s1/2 <= p`2 by XREAL_1:19;
    set q1 = |[p`1+0,p`2+s1/2]|;
    q1 in Ball(u,s1) by A4,A6,A7,Th8;
    then q1 in h_strip(G,j) by A5;
    then ex r2,s2 st q1 = |[r2,s2]| & G*(1,j)`2 <= s2 & s2 <= G*(1,j+1)`2 by A2
;
    then
A9: p`2+s1/2 <= G*(1,j+1)`2 by SPPOL_2:1;
    G*(1,j)`2 < G*(1,j)`2 + s1/2 by A4,XREAL_1:29,215;
    then
A10: G*(1,j)`2 < p`2 by A8,XXREAL_0:2;
    p`2 < p`2 + s1/2 by A4,XREAL_1:29,215;
    then p`2 < G*(1,j+1)`2 by A9,XXREAL_0:2;
    hence thesis by A6,A10;
  end;
  let x be object;
  assume x in { |[r,s]| : G*(1,j)`2 < s & s < G*(1,j+1)`2 };
  then consider r,s such that
A11: x = |[r,s]| and
A12: G*(1,j)`2 < s and
A13: s < G*(1,j+1)`2;
  reconsider u = |[r,s]| as Point of Euclid 2 by TOPREAL3:8;
  G*(1,j+1)`2-s > 0 & s - G*(1,j)`2 > 0 by A12,A13,XREAL_1:50;
  then min(s-G*(1,j)`2,G*(1,j+1)`2-s) > 0 by XXREAL_0:15;
  then
A14: u in Ball(u,min(s-G*(1,j)`2,G*(1,j+1)`2-s)) by Th1;
A15: Ball(u,min(s-G*(1,j)`2,G*(1,j+1)`2-s)) c= h_strip(G,j)
  proof
    let y be object;
A16: Ball(u,min(s-G*(1,j)`2,G*(1,j+1)`2-s)) = { v : dist(u,v)<min(s-G*(1,j
    )`2,G*(1,j+1)`2-s)} by METRIC_1:17;
    assume y in Ball(u,min(s-G*(1,j)`2,G*(1,j+1)`2-s));
    then consider v such that
A17: v = y and
A18: dist(u,v)<min(s-G*(1,j)`2,G*(1,j+1)`2-s) by A16;
    reconsider q = v as Point of TOP-REAL 2 by TOPREAL3:8;
    (s - q`2)^2 >= 0 & (s - q`2)^2 + 0 <= (r - q`1)^2 + (s - q`2)^2 by
XREAL_1:6,63;
    then
A19: sqrt (s - q`2)^2 <= sqrt ((r - q`1)^2 + (s - q`2)^2) by SQUARE_1:26;
A20: q = |[q`1,q`2]| by EUCLID:53;
    then sqrt ((r - q`1)^2 + (s - q`2)^2) < min(s-G*(1,j)`2,G*(1,j+1 )`2-s )
    by A18,Th6;
    then sqrt (s - q`2)^2 <= min(s-G*(1,j)`2,G* (1,j+1)`2-s) by A19,XXREAL_0:2;
    then
A21: |.s-q`2.| <= min(s-G*(1,j)`2,G*(1,j+1)`2-s) by COMPLEX1:72;
    then
A22: |.s-q`2.| <= s-G*(1,j)`2 by XXREAL_0:22;
A23: |.s-q`2.| <= G* (1,j+1)`2-s by A21,XXREAL_0:22;
    per cases;
    suppose
A24:  s <= q`2;
      then
A25:  q`2-s >= 0 by XREAL_1:48;
      |.s-q`2.| = |.-(s-q`2).| by COMPLEX1:52
        .= q`2 - s by A25,ABSVALUE:def 1;
      then
A26:  q`2 <= G*(1,j+1)`2 by A23,XREAL_1:9;
      G*(1,j)`2 <= q`2 by A12,A24,XXREAL_0:2;
      hence thesis by A2,A17,A20,A26;
    end;
    suppose
A27:  s >= q`2;
      then s-q`2 >= 0 by XREAL_1:48;
      then |.s-q`2.| = s - q`2 by ABSVALUE:def 1;
      then
A28:  G*(1,j)`2 <= q`2 by A22,XREAL_1:10;
      q`2 <= G*(1,j+1)`2 by A13,A27,XXREAL_0:2;
      hence thesis by A2,A17,A20,A28;
    end;
  end;
  reconsider B = Ball(u,min(s-G*(1,j)`2,G*(1,j+1)`2-s)) as Subset of TOP-REAL2
  by TOPREAL3:8;
  B is open by Th3;
  hence thesis by A11,A14,A15,TOPS_1:22;
end;
