reserve i,j,k for Nat,
  r,s,r1,r2,s1,s2,sb,tb for Real,
  x for set,
  GX for non empty TopSpace;
reserve GZ for non empty TopSpace;
reserve f for non constant standard special_circular_sequence,
  G for non empty-yielding Matrix of TOP-REAL 2;

theorem Th17:
  for G being Matrix of TOP-REAL 2 holds v_strip(G,j) is closed
proof
  let G be Matrix of TOP-REAL 2;
  now
    per cases;
    case
A1:   j<1;
A2:   now
        assume j >= len G;
        then v_strip(G,j)={ |[s,r]| where s,r is Real: G*(j,1)`1 <= s }
        by GOBOARD5:def 1;
        hence thesis by Th15;
      end;
      now
        assume j<len G;
        then v_strip(G,j) = { |[s,r]| where s,r is Real:
        s <= G*(j+1,1)`1 } by A1,GOBOARD5:def 1;
        hence thesis by Th14;
      end;
      hence thesis by A2;
    end;
    case
      1 <= j & j < len G;
      then
A3:   v_strip(G,j) = { |[s,r]| where s,r is Real:
      G*(j,1)`1 <= s & s <= G*(j+1,1)`1 } by GOBOARD5:def 1;
      reconsider P2={ |[s1,r1]| where s1,r1 is Real:
      s1<= G*(j+1,1)`1 } as Subset of TOP-REAL 2
      by Lm7;
      reconsider P1={ |[s1,r1]| where s1,r1 is Real:
      G*(j,1)`1 <= s1} as Subset of TOP-REAL 2 by Lm9;
A4:   { |[s,r]| where s,r is Real :
      G*(j,1)`1 <= s & s <= G*(j+1,1)`1 }=
      { |[s1,r1]| where s1,r1 is Real: G*(j
      ,1)`1 <= s1} /\ {|[s2,r2]| where s2,r2 is Real: s2 <= G*(j+1,1)`1 }
      proof
A5:     { |[s1,r1]| where s1,r1 is Real: G*(j,1)`1 <= s1} /\
        {|[s2,r2]| where s2,r2 is Real: s2 <= G*(j+1,1)`1
        } c= { |[s,r]| where s,r is Real : G*(j,1)`1 <= s & s <= G*(j+1,1)`1 }
        proof
          let x be object;
          assume
A6:       x in { |[s1,r1]| where s1,r1 is Real :
          G*(j,1)`1 <= s1} /\ {|[s2,r2]| where s2,r2 is Real: s2 <= G
          * (j+1,1)`1 };
          then
A7:       x in {|[s2,r2]| where s2,r2 is Real : s2 <= G*(j+1,1)`1 }
          by XBOOLE_0:def 4;
          x in { |[s1,r1]| where s1,r1 is Real: G*(j,1)`1 <= s1}
          by A6,XBOOLE_0:def 4;
          then ex s1,r1 st |[s1,r1]|=x & G*(j,1)`1 <= s1;
          then consider r1,s1 such that
A8:       |[s1,r1]|=x and
A9:       G*(j,1)`1 <= s1;
          consider s2,r2 such that
A10:      |[s2,r2]|=x and
A11:      s2 <= G*(j+1,1)`1 by A7;
          s1=s2 by A8,A10,SPPOL_2:1;
          hence thesis by A8,A9,A11;
        end;
A12:    { |[s,r]| where s,r is Real: G*(j,1)`1 <= s & s <= G*(j+1,1)`1 } c=
        {|[s1,r1]| where s1,r1 is Real: G*(j,1)`1 <= s1 }
        proof
          let x be object;
          assume x in { |[s,r]| where s,r is Real:
          G*(j,1)`1 <= s & s <= G*(j+1,1)`1 };
          then ex s,r st x=|[s,r]| & G*(j,1)`1 <= s & s <= G*(j+1,1)`1;
          hence thesis;
        end;
        { |[s,r]| where s,r is Real:
        G*(j,1)`1 <= s & s <= G*(j+1,1)`1 } c= {|[s1,r1]| where s1,r1 is Real:
        s1 <= G*(j+1,1)`1 }
        proof
          let x be object;
          assume x in { |[s,r]| where s,r is Real:
          G*(j,1)`1 <= s & s <= G*(j+1,1)`1 };
          then ex s,r st x=|[s,r]| & G*(j,1)`1 <= s & s <= G*(j+1,1)`1;
          hence thesis;
        end;
        then { |[s,r]| where s,r is Real: G*(j,1)`1 <= s & s <= G*(j+1,1)`1 }
        c=
        { |[s1,r1]| where s1,r1 is Real: G*(j,1)`1 <= s1} /\
        {|[s2,r2]| where s2,r2 is Real: s2 <= G*(j+1,1)`1 } by A12,XBOOLE_1:19;
        hence thesis by A5;
      end;
      P1 is closed & P2 is closed by Th14,Th15;
      hence thesis by A3,A4,TOPS_1:8;
    end;
    case
      j >= len G;
      then v_strip(G,j) = { |[s,r]| where s,r is Real:
      G*(j,1)`1 <= s } by GOBOARD5:def 1;
      hence thesis by Th15;
    end;
  end;
  hence thesis;
end;
