reserve i,s,t,m,n,k for Nat,
        c,d,e for Element of NAT,
        fn for FinSequence of NAT,
        x,y for Integer;
reserve p for Prime;

theorem Th17:
  n>1 & s,n are_coprime & t,n are_coprime &
  order(s,n),order(t,n) are_coprime implies
  order(s*t,n) = order(s,n)*order(t,n)
proof assume A1:n>1 & s,n are_coprime & t,n are_coprime &
   order(s,n),order(t,n) are_coprime;
   then s gcd n = 1 & t gcd n = 1 by INT_2:def 3; then
   (s*t) gcd n = 1 by WSIERP_1:7;
   then A2:(s*t),n are_coprime by INT_2:def 3;
   set L = order(s,n)*order(t,n);
A3:((s*t)|^order(s*t,n)) mod n = 1 by A1,A2,PEPIN:def 2
               .= 1 mod n by A1,PEPIN:5;
   then ((s*t)|^order(s*t,n)|^order(s,n)) mod n = 1|^order(s,n) mod n
   by INT_4:8;
   then (s*t)|^(order(s*t,n) * order(s,n)) mod n
         = 1|^order(s,n) mod n by NEWTON:9
        .= 1 mod n  .= 1 by A1,PEPIN:5;
   then (s*t)|^(order(s,n))|^order(s*t,n) mod n = 1 by NEWTON:9;
   then (s|^order(s,n)*t|^order(s,n))|^order(s*t,n) mod n = 1 by NEWTON:7;then
A4:((s|^order(s,n))|^order(s*t,n) * (t|^order(s,n))|^order(s*t,n)) mod n = 1
                                                                  by NEWTON:7;
   s|^order(s,n) mod n = 1 by A1,PEPIN:def 2  .= 1 mod n by A1,PEPIN:5;
   then (s|^order(s,n))|^order(s*t,n) mod n = 1|^order(s*t,n) mod n by INT_4:8
                            .= 1 mod n;
   then (s|^order(s,n))|^order(s*t,n),1 are_congruent_mod n by A1,NAT_D:64;
   then (s|^order(s,n))|^order(s*t,n)*(t|^order(s,n))|^order(s*t,n),
        1*(t|^order(s,n))|^order(s*t,n) are_congruent_mod n by INT_4:11;
   then (t|^order(s,n))|^order(s*t,n) mod n = 1 by A4,NAT_D:64;
   then A5:t|^(order(s,n) * order(s*t,n)) mod n = 1 by NEWTON:9;
A6:order(t,n) divides order(s*t,n) by A1,A5,PEPIN:47,PEPIN:3;
   ((s*t)|^order(s*t,n))|^order(t,n) mod n = 1|^order(t,n) mod n
                                                              by A3,INT_4:8;
   then (s*t)|^(order(s*t,n) * order(t,n)) mod n
             = 1|^order(t,n) mod n by NEWTON:9
            .= 1 mod n  .= 1 by A1,PEPIN:5;
    then ((s*t)|^order(t,n))|^order(s*t,n) mod n = 1 by NEWTON:9;then
    (s|^order(t,n)*t|^order(t,n))|^order(s*t,n) mod n = 1 by NEWTON:7;then
A7:((s|^order(t,n))|^order(s*t,n) * (t|^order(t,n))|^order(s*t,n)) mod n = 1
                                                                 by NEWTON:7;
   t|^order(t,n) mod n = 1 by A1,PEPIN:def 2  .= 1 mod n by A1,PEPIN:5;
   then (t|^order(t,n))|^order(s*t,n) mod n = 1|^order(s*t,n) mod n by INT_4:8
                            .= 1 mod n;
   then (t|^order(t,n))|^order(s*t,n),1 are_congruent_mod n by A1,NAT_D:64;
   then (t|^order(t,n))|^order(s*t,n)*(s|^order(t,n))|^order(s*t,n),
        1*(s|^order(t,n))|^order(s*t,n) are_congruent_mod n by INT_4:11;
   then (s|^order(t,n))|^order(s*t,n) mod n = 1 by A7,NAT_D:64;
   then s|^(order(t,n) * order(s*t,n)) mod n = 1 by NEWTON:9;
   then order(s,n) divides order(s*t,n) by A1,PEPIN:3,47;
   then A8:L divides order(s*t,n) by A6,A1,PEPIN:4;
   order(s,n) divides L & order(t,n) divides L by NAT_D:def 3;
   then s|^L mod n = 1 & t|^L mod n = 1 by A1,PEPIN:48;
   then s|^L,1 are_congruent_mod n & t|^L,1 are_congruent_mod n by A1,PEPIN:39;
   then (s|^L)*(t|^L),1*1 are_congruent_mod n by INT_1:18;
   then (s*t)|^L,1 are_congruent_mod n by NEWTON:7;
   then (s*t)|^L mod n = 1 mod n by NAT_D:64   .= 1 by A1,PEPIN:5;
   then order(s*t,n) divides L by A1,A2,PEPIN:47;
  hence thesis by A8,NAT_D:5;
end;
