
theorem Th17:
for f1,f2 be PartFunc of REAL,REAL, x0 be Real st
 f1 is_left_divergent_to-infty_in x0 &
 (for r be Real st r<x0 ex g be Real st r<g & g<x0 & g in dom(f1+f2)) &
 (ex r be Real st 0<r & f2|(].x0-r,x0.[) is bounded_above)
holds
  f1+f2 is_left_divergent_to-infty_in x0
proof
    let f1,f2 be PartFunc of REAL,REAL, x0 be Real;
    assume that
A1:  f1 is_left_divergent_to-infty_in x0 and
A2:  for r be Real st r<x0 ex g be Real st r<g & g<x0 & g in dom(f1+f2);
  given r be Real such that
A3: 0<r and
A4: f2|(].x0-r,x0.[) is bounded_above;
  now
    let seq be Real_Sequence such that
A5: seq is convergent and
A6: lim seq=x0 and
A7: rng seq c=dom(f1+f2) /\ left_open_halfline(x0);
    x0-r<x0 by A3,Lm2;
    then consider k be Nat such that
A8: for n be Nat st k<=n holds x0-r<seq.n by A5,A6,LIMFUNC2:1;
A9: dom(f1+f2)/\left_open_halfline(x0) c=dom(f1+f2) by XBOOLE_1:17;
A10: rng(seq^\k)c=rng seq by VALUED_0:21;
    then
A11: rng(seq^\k)c=dom(f1+f2) by A7,A9;
A12: dom(f1+f2)=dom f1/\dom f2 by VALUED_1:def 1;
    then
A13: dom(f1+f2)c=dom f2 by XBOOLE_1:17;
    then
A14: rng(seq^\k)c=dom f2 by A11;
    dom(f1+f2)c=dom f1 by A12,XBOOLE_1:17;
    then
A15: rng(seq^\k)c=dom f1 by A11;
    then rng(seq^\k)c=dom f1/\dom f2 by A14,XBOOLE_1:19;
    then
A16: f1/*(seq^\k)+f2/*(seq^\k)=(f1+f2)/*(seq^\k) by RFUNCT_2:8
      .=((f1+f2)/*seq)^\k by A7,A9,VALUED_0:27,XBOOLE_1:1;
A17: dom(f1+f2)/\ left_open_halfline(x0) c=left_open_halfline(x0) by
XBOOLE_1:17;
    then rng(seq^\k)c=left_open_halfline(x0) by A10,A7;
    then
A18: rng(seq^\k)c=dom f1/\left_open_halfline(x0) by A15,XBOOLE_1:19;

A19: now
      consider r1 be Real such that
A20:  for g being object st g in ].x0-r,x0.[/\dom f2 holds f2.g<=r1 by A4,
RFUNCT_1:70;
      take r2=r1+1;
      let n be Nat;
A21: n in NAT by ORDINAL1:def 12;
      x0-r<seq.(n+k) by A8,NAT_1:12;
      then
A22:  x0-r<(seq^\k).n by NAT_1:def 3;
A23:  (seq^\k).n in rng(seq^\k) by VALUED_0:28;
      then (seq^\k).n in left_open_halfline(x0) by A17,A10,A7;
      then (seq^\k).n in {g1 where g1 is Real: g1<x0} by XXREAL_1:229;
      then ex g be Real st g=(seq^\k).n & g<x0;
      then (seq^\k).n in {g2 where g2 is Real: x0-r<g2 & g2<x0} by A22;
      then (seq^\k).n in ].x0-r,x0.[ by RCOMP_1:def 2;
      then (seq^\k).n in ].x0-r,x0.[/\dom f2 by A14,A23,XBOOLE_0:def 4;
      then f2.((seq^\k).n)<r1+1 by A20,XREAL_1:39;
      hence (f2/*(seq^\k)).n<r2 by A11,A13,FUNCT_2:108,XBOOLE_1:1,A21;
    end;
    lim(seq^\k)=x0 by A5,A6,SEQ_4:20;
    then f1/*(seq^\k) is divergent_to-infty by A1,A5,A18,LIMFUNC2:def 3;
    then f1/*(seq^\k)+f2/*(seq^\k) is divergent_to-infty
      by A19,LIMFUNC1:12,SEQ_2:def 3;
    hence (f1+f2)/*seq is divergent_to-infty by A16,LIMFUNC1:7;
  end;
  hence thesis by A2,LIMFUNC2:def 3;
end;
