reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;

theorem Th17:
  for f,a,b,c st a in (L~f)` & b in (L~f)` & c in (L~f)` & (not ex
C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` & a in C & b in C)) &
  (not ex C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` & b in C & c
in C)) holds ex C be Subset of TOP-REAL 2 st C is_a_component_of (L~f)` & a in
  C & c in C
proof
  let f,a,b,c such that
A1: a in (L~f)` and
A2: b in (L~f)` and
A3: c in (L~f)` and
A4: not ex C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` & a
  in C & b in C) and
A5: not ex C be Subset of TOP-REAL 2 st (C is_a_component_of (L~f)` & b
  in C & c in C);
A6: LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
A7: RightComp f is_a_component_of (L~f)` by GOBOARD9:def 2;
  per cases by A1,A2,A4,Th15;
  suppose
A8: a in LeftComp f & b in RightComp f;
    now
      per cases by A2,A3,A5,Th15;
      suppose
        b in LeftComp f & c in RightComp f;
        then LeftComp f meets RightComp f by A8,XBOOLE_0:3;
        hence thesis by GOBRD14:14;
      end;
      suppose
        b in RightComp f & c in LeftComp f;
        hence thesis by A6,A8;
      end;
    end;
    hence thesis;
  end;
  suppose
A9: a in RightComp f & b in LeftComp f;
    now
      per cases by A2,A3,A5,Th15;
      suppose
        b in RightComp f & c in LeftComp f;
        then LeftComp f meets RightComp f by A9,XBOOLE_0:3;
        hence thesis by GOBRD14:14;
      end;
      suppose
        b in LeftComp f & c in RightComp f;
        hence thesis by A7,A9;
      end;
    end;
    hence thesis;
  end;
end;
