reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th17:
  (UMP C)`2 < (UMP L~Cage(C,n))`2
proof
  set p = UMP L~Cage(C,n), u = UMP C, w = (W-bound C + E-bound C) / 2;
A1: u`1 = w by EUCLID:52;
A2: p in L~Cage(C,n) by JORDAN21:30;
A3: u = |[u`1,u`2]| by EUCLID:53;
A4: p = |[p`1,p`2]| by EUCLID:53;
A5: C misses L~Cage(C,n) by JORDAN10:5;
A6: u in C by JORDAN21:30;
A7: w = (W-bound L~Cage(C,n) + E-bound L~Cage(C,n)) / 2 by JORDAN1G:33;
  then
A8: p`1 = w by EUCLID:52;
  assume
A9: not thesis;
  per cases by A9,XXREAL_0:1;
  suppose
    u`2 = p`2;
    hence thesis by A1,A8,A4,A3,A5,A6,A2,XBOOLE_0:3;
  end;
  suppose
A10: u`2 > p`2;
A11: proj2.:(L~Cage(C,n) /\ Vertical_Line w) is non empty bounded_above by A7,
JORDAN21:12,13;
A12: p`2 = upper_bound (proj2.:(L~Cage(C,n) /\ Vertical_Line w))
by A7,EUCLID:52;
A13: north_halfline p \ {p} misses L~Cage(C,n)
    proof
      assume north_halfline p \ {p} meets L~Cage(C,n);
      then consider x being object such that
A14:  x in north_halfline p \ {p} and
A15:  x in L~Cage(C,n) by XBOOLE_0:3;
      reconsider x as Point of TOP-REAL 2 by A15;
A16:  x in north_halfline p by A14,XBOOLE_0:def 5;
      then
A17:  x`2 >= p`2 by TOPREAL1:def 10;
A18:  x`1 = w by A8,A16,TOPREAL1:def 10;
      then x in Vertical_Line w;
      then
A19:  x in L~Cage(C,n) /\ Vertical_Line w by A15,XBOOLE_0:def 4;
      proj2.x = x`2 by PSCOMP_1:def 6;
      then x`2 in proj2.:(L~Cage(C,n) /\ Vertical_Line w) by A19,FUNCT_2:35;
      then
A20:  x`2 <= p`2 by A12,A11,SEQ_4:def 1;
      not x in {p} by A14,XBOOLE_0:def 5;
      then x <> p by TARSKI:def 1;
      then x`2 <> p`2 by A8,A18,TOPREAL3:6;
      hence contradiction by A17,A20,XXREAL_0:1;
    end;
    north_halfline p \ {p} is convex by JORDAN21:6;
    then
A21: north_halfline p \ {p} c= UBD L~Cage(C,n) or north_halfline p \ {p}
    c= BDD L~Cage(C,n) by A13,JORDAN1K:19;
A22: UBD L~Cage(C,n) c= UBD C by JORDAN10:13;
A23: not u in {p} by A10,TARSKI:def 1;
    u in north_halfline p by A1,A8,A10,TOPREAL1:def 10;
    then
A24: u in north_halfline p \ {p} by A23,XBOOLE_0:def 5;
A25: UBD C misses C by JORDAN21:10;
    north_halfline p is not bounded by JORDAN2C:122;
    then
A26: north_halfline p \ {p} is not bounded by JORDAN21:1,TOPREAL6:90;
    BDD L~Cage(C,n) is bounded by JORDAN2C:106;
    then u in UBD L~Cage(C,n) by A21,A26,A24,RLTOPSP1:42;
    hence thesis by A6,A22,A25,XBOOLE_0:3;
  end;
end;
