reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem Th17:
  for i,j being Nat st 1 <= i & i+1 <= len G & 1 <= j &
j+1 <= width G holds p in cell(G,i,j) iff G*(i,j)`1 <= p`1 & p`1 <= G*(i+1,j)`1
  & G*(i,j)`2 <= p`2 & p`2 <= G*(i,j+1)`2
proof
  let i,j be Nat such that
A1: 1 <= i and
A2: i+1 <= len G and
A3: 1 <= j and
A4: j+1 <= width G;
A5: i < len G & j < width G by A2,A4,NAT_1:13;
  then
A6: h_strip(G,j) = { |[r,s]| : G*(i,j)`2 <= s & s <= G*(i,j+1)`2 } by A1,A3,
GOBOARD5:5;
A7: v_strip(G,i) = { |[r,s]| : G*(i,j)`1 <= r & r <= G*(i+1,j)`1 } by A1,A3,A5,
GOBOARD5:8;
  hereby
    assume
A8: p in cell(G,i,j);
    then p in v_strip(G,i) by XBOOLE_0:def 4;
    then ex r,s st |[r,s]| = p & G*(i,j)`1 <= r & r <= G*(i+1,j)`1 by A7;
    hence G*(i,j)`1 <= p`1 & p`1 <= G*(i+1,j)`1 by EUCLID:52;
    p in h_strip(G,j) by A8,XBOOLE_0:def 4;
    then ex r,s st |[r,s]| = p & G*(i,j)`2 <= s & s <= G*(i,j+1)`2 by A6;
    hence G*(i,j)`2 <= p`2 & p`2 <= G*(i,j+1)`2 by EUCLID:52;
  end;
  assume that
A9: G*(i,j)`1 <= p`1 & p`1 <= G*(i+1,j)`1 and
A10: G*(i,j)`2 <= p`2 & p`2 <= G*(i,j+1)`2;
A11: p = |[p`1,p`2]| by EUCLID:53;
  then
A12: p in h_strip(G,j) by A6,A10;
  p in v_strip(G,i) by A7,A9,A11;
  hence thesis by A12,XBOOLE_0:def 4;
end;
