reserve x, y for object, X for set,
  i, j, k, l, n, m for Nat,
  D for non empty set,
  K for commutative Ring,
  a,b for Element of K,
  perm, p, q for Element of Permutations(n),
  Perm,P for Permutation of Seg n,
  F for Function of Seg n,Seg n,
  perm2, p2, q2, pq2 for Element of Permutations(n+2),
  Perm2 for Permutation of Seg (n+2);
reserve s for Element of 2Set Seg (n+2);

theorem Th17:
  for p be Element of Permutations(k+1) st p.(k+1) <> k+1 ex tr be
Element of Permutations(k+1) st tr is being_transposition & tr.(p.(k+1)) = k+1
  & (tr*p).(k+1) = k+1
proof
  set k1=k+1;
  let p be Element of Permutations(k1) such that
A1: p.k1<>k1;
  reconsider p9=p as Permutation of Seg k1 by MATRIX_1:def 12;
A2: dom p9=Seg k1 by FUNCT_2:52;
A3: rng p9=Seg k1 by FUNCT_2:def 3;
A4: k1 in Seg k1 by FINSEQ_1:3;
  then
A5: p.k1 in Seg k1 by A2,A3,FUNCT_1:def 3;
  then p.k1<=k1 by FINSEQ_1:1;
  then p.k1 < k1 by A1,XXREAL_0:1;
  then consider tr be Element of Permutations(k1) such that
A6: tr is being_transposition and
A7: tr.(p.k1)=k1 by A4,A5,Th16;
  reconsider tr9=tr as Permutation of Seg k1 by MATRIX_1:def 12;
  dom tr9=Seg k1 by FUNCT_2:52;
  then dom (tr*p)= Seg k1 by A2,A3,RELAT_1:27;
  then (tr*p).k1=tr.(p.k1) by FINSEQ_1:3,FUNCT_1:12;
  hence thesis by A6,A7;
end;
