reserve k,t,i,j,m,n for Nat,
  x,y,y1,y2 for object,
  D for non empty set;
reserve K for Field,
  V for VectSp of K,
  a for Element of K,
  W for Element of V;
reserve KL1,KL2,KL3 for Linear_Combination of V,
  X for Subset of V;
reserve s for FinSequence,
  V1,V2,V3 for finite-dimensional VectSp of K,
  f,f1,f2 for Function of V1,V2,
  g for Function of V2,V3,
  b1 for OrdBasis of V1,
  b2 for OrdBasis of V2,
  b3 for OrdBasis of V3,
  v1,v2 for Vector of V2,
  v,w for Element of V1;
reserve p2,F for FinSequence of V1,
  p1,d for FinSequence of K,
  KL for Linear_Combination of V1;

theorem Th17:
  for a be FinSequence of K, p being FinSequence of V1 st len p =
  len a holds f is additive homogeneous implies f*lmlt(a,p) = lmlt(a,f*p)
proof
  let a be FinSequence of K, p be FinSequence of V1;
  assume len p = len a;
  then
A1: dom p = dom a by FINSEQ_3:29;
  dom f = the carrier of V1 by FUNCT_2:def 1;
  then rng p c= dom f by FINSEQ_1:def 4;
  then
A2: dom p = dom (f*p) by RELAT_1:27;
  assume
A3: f is additive homogeneous;
A4: now
    set P = f*p;
    let k be Nat;
    assume
A5: k in dom (f*lmlt(a,p));
A6: dom (f*lmlt(a,p)) c= dom lmlt(a,p) by RELAT_1:25;
    then k in dom lmlt(a,p) by A5;
    then
A7: k in dom p by A1,Th12;
    then
A8: p/.k = p.k by PARTFUN1:def 6;
A9: k in dom lmlt(a,f*p) by A1,A2,A7,Th12;
A10: a/.k = a.k by A1,A7,PARTFUN1:def 6;
A11: P/.k = (f*p).k by A2,A7,PARTFUN1:def 6;
    thus (f*lmlt(a,p)).k = f.(lmlt(a,p).k) by A5,FUNCT_1:12
      .= f.((the lmult of V1).(a.k,p.k)) by A5,A6,FUNCOP_1:22
      .= f.((a/.k)*(p/.k)) by A10,A8,VECTSP_1:def 12
      .= (a/.k)*(f.(p/.k)) by A3,MOD_2:def 2
      .= (a/.k)*(P/.k) by A7,A8,A11,FUNCT_1:13
      .= (the lmult of V2).(a.k,(f*p).k) by A10,A11,VECTSP_1:def 12
      .= lmlt(a,f*p).k by A9,FUNCOP_1:22;
  end;
  dom lmlt(a,p) = dom p by A1,Th12
    .= dom lmlt(a,f*p) by A1,A2,Th12;
  then len lmlt(a,p) = len lmlt(a,f*p) by FINSEQ_3:29;
  then len (f*lmlt(a,p)) = len lmlt(a,f*p) by FINSEQ_2:33;
  hence thesis by A4,FINSEQ_2:9;
end;
