reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th17:
  v1 + w1 |-- b1 = (v1 |-- b1) + (w1 |-- b1)
proof
  set vb=v1 |-- b1;
  set wb=w1 |-- b1;
  set vwb=v1+w1 |-- b1;
  consider L1 be Linear_Combination of V1 such that
A1: v1 = Sum(L1) & Carrier L1 c= rng b1 and
A2: for k st 1<=k & k<=len vb holds vb/.k = L1.(b1/.k) by MATRLIN:def 7;
  consider L3 be Linear_Combination of V1 such that
A3: v1+w1 = Sum(L3) & Carrier L3 c= rng b1 and
A4: for k st 1<=k & k<=len vwb holds vwb/.k = L3.(b1/.k) by MATRLIN:def 7;
A5: len wb=len b1 by MATRLIN:def 7;
  reconsider rb1=rng b1 as Basis of V1 by MATRLIN:def 2;
  consider L2 be Linear_Combination of V1 such that
A6: w1 = Sum(L2) & Carrier L2 c= rng b1 and
A7: for k st 1<=k & k<=len wb holds wb/.k = L2.(b1/.k) by MATRLIN:def 7;
A8: len vb=len b1 by MATRLIN:def 7;
A9: len vwb=len b1 by MATRLIN:def 7;
  then reconsider
  vb,wb,vwb as Element of (len b1)-tuples_on the carrier of K by A8,A5,
FINSEQ_2:92;
  rb1 is linearly-independent by VECTSP_7:def 3;
  then
A10: L3=L1+L2 by A1,A6,A3,MATRLIN:6;
  now
A11: dom b1=Seg len b1 by FINSEQ_1:def 3;
    let i such that
A12: i in Seg len b1;
A13: 1<=i & i<=len b1 by A12,FINSEQ_1:1;
    dom wb=dom b1 by A5,FINSEQ_3:29;
    then
A14: wb.i=wb/.i by A12,A11,PARTFUN1:def 6;
    dom vb=dom b1 by A8,FINSEQ_3:29;
    then
A15: vb.i=vb/.i by A12,A11,PARTFUN1:def 6;
    dom vwb=dom b1 by A9,FINSEQ_3:29;
    then vwb.i=vwb/.i by A12,A11,PARTFUN1:def 6;
    hence vwb.i = (L1+L2).(b1/.i) by A4,A9,A10,A13
      .= L1.(b1/.i)+L2.(b1/.i) by VECTSP_6:22
      .= vb/.i +L2.(b1/.i) by A2,A8,A13
      .= vb/.i +wb/.i by A7,A5,A13
      .= (vb+wb).i by A12,A15,A14,FVSUM_1:18;
  end;
  hence thesis by FINSEQ_2:119;
end;
