
theorem Th17:
for A be non empty closed_interval Subset of REAL, T be sequence of divs A st
 vol A > 0 & (for n be Nat holds T.n = EqDiv(A,2|^n)) holds
  delta T is 0-convergent non-zero
proof
    let A be non empty closed_interval Subset of REAL;
    let T be sequence of divs A;
    assume that
A1:  vol A > 0 and
A2:  for n be Nat holds T.n = EqDiv(A,2|^n);

A3: for n be Nat holds (delta T).n = 2*(vol A)*(2"|^(n+1))
    proof
     let n be Nat;
     n is Element of NAT by ORDINAL1:def 12; then
     (delta T).n = delta(T.n) by INTEGRA3:def 2; then
     (delta T).n = delta(EqDiv(A,2|^n)) by A2; then
A4:  (delta T).n = max rng (upper_volume(chi(A,A),EqDiv(A,2|^n)))
       by INTEGRA3:def 1;

A5:  for k be Nat st k in dom EqDiv(A,2|^n)
      holds (upper_volume(chi(A,A),EqDiv(A,2|^n))).k = 2*(vol A)*(2"|^(n+1))
     proof
      let k be Nat;
      assume A6: k in dom EqDiv(A,2|^n);
      2|^n > 0 by NEWTON:83; then
      EqDiv(A,2|^n) divide_into_equal 2|^n by A1,Def1; then
      vol divset(EqDiv(A,2|^n),k) = (vol A)/(2|^n) by A6,Th15; then
      upper_volume(chi(A,A),EqDiv(A,2|^n)).k
       = (vol A)/(2|^n) by A6,INTEGRA1:20
      .= (vol A)/(2|^n * 2)*2 by XCMPLX_1:92
      .= (vol A)/(2|^(n+1))*2 by NEWTON:6
      .= (vol A)*(2|^(n+1))"*2 by XCMPLX_0:def 9
      .= 2*(vol A)*(2|^(n+1))";
      hence thesis by Th16;
     end;

     now let q be object;
      assume q in rng (upper_volume(chi(A,A),EqDiv(A,2|^n))); then
      consider p be Element of NAT such that
A7:    p in dom (upper_volume(chi(A,A),EqDiv(A,2|^n))) &
       q = (upper_volume(chi(A,A),EqDiv(A,2|^n))).p by PARTFUN1:3;
      len (upper_volume(chi(A,A),EqDiv(A,2|^n))) = len EqDiv(A,2|^n)
        by INTEGRA1:def 6; then
      dom (upper_volume(chi(A,A),EqDiv(A,2|^n))) = dom EqDiv(A,2|^n)
        by FINSEQ_3:29; then
      q = 2*(vol A)*(2"|^(n+1)) by A5,A7;
      hence q in {2*(vol A)*(2"|^(n+1))} by TARSKI:def 1;
     end; then
     rng (upper_volume(chi(A,A),EqDiv(A,2|^n)))
       c= {2*(vol A)*(2"|^(n+1))}; then
     rng (upper_volume(chi(A,A),EqDiv(A,2|^n)))
       = {2*(vol A)*(2"|^(n+1))} by ZFMISC_1:33;
     hence (delta T).n = 2*(vol A)*(2"|^(n+1)) by A4,XXREAL_2:11;
    end;

    deffunc SEQ(Nat) = (2") to_power ($1+1);

    consider seq be Real_Sequence such that
A8:  for n be Nat holds seq.n = SEQ(n) from SEQ_1:sch 1;

A9: seq is convergent & lim seq = 0 by A8,SERIES_1:1;

    for n be Nat holds (delta T).n = (2*(vol A))*(seq.n)
    proof
     let n be Nat;
     seq.n = 2" to_power (n+1) by A8
      .= 2"|^(n+1) by POWER:41;
     hence (delta T).n = 2*(vol A)*seq.n by A3;
    end; then
A10:delta T = (2*(vol A))(#)seq by SEQ_1:9; then
A11:delta T is convergent by A8,SERIES_1:1,SEQ_2:7;

A12:lim (delta T) = (2*(vol A))*0 by A9,A10,SEQ_2:8
      .= 0;

    now assume 0 in rng(delta T); then
     consider m be Element of NAT such that
A13:  m in dom(delta T) & 0 = (delta T).m by PARTFUN1:3;
A14: 2*(vol A)*(2"|^(m+1)) = 0 by A3,A13;
     2*(vol A) <> 0 & 2"|^(m+1) <> 0 by A1,NEWTON:83;
     hence contradiction by A14,XCMPLX_1:6;
    end;
    hence thesis by A11,A12,FDIFF_1:def 1,ORDINAL1:def 15;
end;
