reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th17:
  Am is dense implies weight TM c= omega *` card Am
proof
  assume
A1: Am is dense;
  per cases;
  suppose
    TM is empty;
    hence thesis;
  end;
  suppose
A2: TM is non empty;
    set TOP=the topology of TM,cTM=the carrier of TM;
    consider metr be Function of[:cTM,cTM:],REAL such that
A3: metr is_metric_of cTM and
A4: Family_open_set(SpaceMetr(cTM,metr))=TOP by PCOMPS_1:def 8;
    reconsider Tm=SpaceMetr(cTM,metr) as non empty MetrSpace by A2,A3,
PCOMPS_1:36;
    defpred P[object,object] means
    ex D2 being set st D2 = $2 &
    for n be Nat st n = $1 holds $2={Ball(p,1/(2|^n))
    where p is Point of Tm:p in Am} & card D2 c= card Am;
A5: for x be object st x in NAT ex y be object st y in bool TOP & P[x,y]
    proof
      defpred P[object] means not contradiction;
      let x be object;
      defpred P1[object] means $1 in Am;
      defpred P2[object] means $1 in Am & P[$1];
      assume x in NAT;
      then reconsider n=x as Element of NAT;
      deffunc F(Point of Tm)=Ball($1,1/(2|^n));
      set BALL1={F(p) where p is Point of Tm:P1[p]};
      set BALL2={F(p) where p is Point of Tm:P2[p]};
      take BALL1;
A6:   BALL1 c=TOP
      proof
        let y be object;
        assume y in BALL1;
        then ex p be Point of Tm st y=F(p) & P1[p];
        hence thesis by A4,PCOMPS_1:29;
      end;
A7:   for p be Point of Tm holds P1[p] iff P2[p];
A8:   BALL1=BALL2 from FRAENKEL:sch 3(A7);
      thus BALL1 in bool TOP by A6;
      take BALL1;
      card BALL2 c=card Am from BORSUK_2:sch 1;
      hence thesis by A8;
    end;
    consider P be sequence of bool TOP such that
A9: for x be object st x in NAT holds P[x,P.x] from FUNCT_2:sch 1(A5);
    reconsider Up=Union P as Subset-Family of TM by XBOOLE_1:1;
A10: for B be Subset of TM st B is open for p be Point of TM st p in B ex
    a be Subset of TM st a in Up & p in a & a c= B
    proof
      let B be Subset of TM;
      assume B is open;
      then
A11:  B in TOP;
      let p be Point of TM such that
A12:  p in B;
      reconsider p9=p as Point of Tm by A2,A3,PCOMPS_2:4;
      consider r be Real such that
A13:  r>0 and
A14:  Ball(p9,r)c=B by A4,A11,A12,PCOMPS_1:def 4;
      consider n be Nat such that
A15:  1/(2|^n)<=r/2 by A13,PREPOWER:92;
      reconsider B2=Ball(p9,1/(2|^n)) as Subset of TM by A2,A3,PCOMPS_2:4;
      2|^n>0 & dist(p9,p9)=0 by METRIC_1:1,PREPOWER:6;
      then
A16:  p9 in B2 by METRIC_1:11;
      B2 in TOP by A4,PCOMPS_1:29;
      then B2 is open;
      then B2 meets Am by A1,A16,TOPS_1:45;
      then consider q be object such that
A17:  q in B2 and
A18:  q in Am by XBOOLE_0:3;
A19:       n in NAT by ORDINAL1:def 12;
      reconsider q as Point of Tm by A17;
      reconsider B3=Ball(q,1/(2|^n)) as Subset of TM by A2,A3,PCOMPS_2:4;
      take B3;
      P[n,P.n] by A9,A19;
      then P.n={Ball(t,1/(2|^n)) where t is Point of Tm:t in Am};
      then B3 in P.n by A18;
      hence B3 in Up by PROB_1:12;
A20:  dist(p9,q)<1/(2|^n) by A17,METRIC_1:11;
      hence p in B3 by METRIC_1:11;
      let y be object;
      assume
A21:  y in B3;
      then reconsider t=y as Point of Tm;
      dist(q,t)<1/(2|^n) by A21,METRIC_1:11;
      then
A22:  dist(q,t)<r/2 by A15,XXREAL_0:2;
      dist(p9,q)<r/2 by A15,A20,XXREAL_0:2;
      then dist(p9,t)<=dist(p9,q)+dist(q,t) & dist(p9,q)+dist(q,t)<r/2+r/2 by
A22,METRIC_1:4,XREAL_1:8;
      then dist(p9,t)<r by XXREAL_0:2;
      then t in Ball(p9,r) by METRIC_1:11;
      hence thesis by A14;
    end;
    Up is Basis of TM by A10,YELLOW_9:32;
    then
A23: weight TM c=card Up by WAYBEL23:73;
A24: card dom P=omega by CARD_1:47,FUNCT_2:def 1;
    for x be object st x in dom P holds card(P.x)c=card Am
     proof let x be object;
       assume
A25:      x in dom P;
       then P[x,P.x] by A9;
      hence thesis by A25;
     end;
    then card Union P c=(omega)*`card Am by A24,CARD_2:86;
    hence thesis by A23;
  end;
end;
