reserve S for non empty non void ManySortedSign,
  A for MSAlgebra over S;
reserve A for non-empty MSAlgebra over S;

theorem Th17:
  for s1,s2 being SortSymbol of S, f being Function st f
  is_e.translation_of A,s1,s2 holds TranslationRel S reduces s1,s2 & f is
  Translation of A,s1,s2
proof
  let s1,s2 be SortSymbol of S, f be Function;
A1: len <*s1,s2*> = 1+1 by FINSEQ_1:44;
A2: len <*f*> = 1 by FINSEQ_1:40;
  assume
A3: f is_e.translation_of A,s1,s2;
  then reconsider
  g = f as Function of (the Sorts of A).s1, (the Sorts of A).s2 by Th11;
A4: <*s1,s2*>.2 = s2;
A5: <*s1,s2*>.1 = s1;
A6: now
    let i be Element of NAT;
    let g be Function, w1,w2 be SortSymbol of S;
    assume i in dom <*f*>;
    then i in {1} by FINSEQ_1:2,38;
    then i = 1 by TARSKI:def 1;
    hence g = <*f*>.i & w1 = <*s1,s2*>.i & w2 = <*s1,s2*>.(i+1) implies g
    is_e.translation_of A,w1,w2 by A3;
  end;
  dom g = (the Sorts of A).s1 by FUNCT_2:def 1;
  then
A7: g = compose(<*f*>, (the Sorts of A).s1) by FUNCT_7:46;
A8: [s1,s2] in TranslationRel S by A3,Th12;
  hence
A9: TranslationRel S reduces s1,s2 by REWRITE1:15;
  <*s1,s2*> is RedSequence of TranslationRel S by A8,REWRITE1:7;
  hence thesis by A7,A9,A1,A2,A5,A4,A6,Def6;
end;
