reserve n for Nat;
reserve K for Field;
reserve a,b,c,d,e,f,g,h,i,a1,b1,c1,d1,e1,f1,g1,h1,i1 for Element of K;
reserve M,N for Matrix of 3,K;
reserve p for FinSequence of REAL;
reserve a,b,c,d,e,f for Real;
reserve u,u1,u2 for non zero Element of TOP-REAL 3;
reserve P for Element of ProjectiveSpace TOP-REAL 3;

theorem Th17:
  for a,b,c,d,e,f being Real
  for P1,P2,P3,P4,P5,P6 being Point of ProjectiveSpace TOP-REAL 3
  for N being invertible Matrix of 3,F_Real
  st not (a = 0 & b = 0 & c = 0 & d = 0 & e = 0 & f = 0 ) &
  P1 in conic(a,b,c,d,e,f) &
  P2 in conic(a,b,c,d,e,f) &
  P3 in conic(a,b,c,d,e,f) &
  P4 in conic(a,b,c,d,e,f) &
  P5 in conic(a,b,c,d,e,f) &
  P6 in conic(a,b,c,d,e,f) holds
  ex a2,b2,c2,d2,e2,f2 be Real st not (a2 = 0 & b2 = 0 & c2 = 0 & d2 = 0 &
  e2 = 0 & f2 = 0 ) &
  (homography(N)).P1 in conic(a2,b2,c2,d2,e2,f2) &
  (homography(N)).P2 in conic(a2,b2,c2,d2,e2,f2) &
  (homography(N)).P3 in conic(a2,b2,c2,d2,e2,f2) &
  (homography(N)).P4 in conic(a2,b2,c2,d2,e2,f2) &
  (homography(N)).P5 in conic(a2,b2,c2,d2,e2,f2) &
  (homography(N)).P6 in conic(a2,b2,c2,d2,e2,f2) 
  proof
    let a,b,c,d,e,f being Real;
    let P1,P2,P3,P4,P5,P6 being Point of ProjectiveSpace TOP-REAL 3;
    let N being invertible Matrix of 3,F_Real;
    assume that
A1: not (a = 0 & b = 0 & c = 0 & d = 0 & e = 0 & f = 0 ) and
A2: P1 in conic(a,b,c,d,e,f) & P2 in conic(a,b,c,d,e,f) &
    P3 in conic(a,b,c,d,e,f) & P4 in conic(a,b,c,d,e,f) &
    P5 in conic(a,b,c,d,e,f) & P6 in conic(a,b,c,d,e,f);
    reconsider M1 = symmetric_3(a,b,c,d/2,e/2,f/2) as Matrix of 3,REAL;
    reconsider NR = MXF2MXR N as Matrix of 3,REAL by MATRIXR1:def 2;
    reconsider M2 = MXF2MXR((MXR2MXF(NR@))~) * M1 *
    MXF2MXR((MXR2MXF NR)~) as Matrix of 3,REAL by Lm03;
    consider ra,rb,rc,rd,re,rf,rg,rh,ri be Element of F_Real such that
A3: MXR2MXF M2 = <* <* ra, rb, rc *> ,
                    <* rd, re, rf *>,
                    <* rg, rh, ri *> *> by Th03;
    MXR2MXF M2 is symmetric by Th14; then
A4: rb = rd & rc = rg & rf = rh by A3,Th06;
    reconsider fa = ra, fe = re,fi = ri,fb = rb,fc = rc,ff = rf as Real;
A5: M2 = symmetric_3(fa,fe,fi,fb,fc,ff) by A3,A4,MATRIXR1:def 1;
    now
      reconsider a2 = ra,b2 = re,c2 = ri,d2 = 2 * rb,e2 = 2 * rc,
                 f2 = 2 * rf as Real; 
      take a2,b2,c2,d2,e2,f2;
      thus not(a2 = 0 & b2 = 0 & c2 = 0 & d2 = 0 & e2 = 0 & f2 = 0) &
      (homography(N)).P1 in conic(a2,b2,c2,d2,e2,f2) &
      (homography(N)).P2 in conic(a2,b2,c2,d2,e2,f2) &
      (homography(N)).P3 in conic(a2,b2,c2,d2,e2,f2) &
      (homography(N)).P4 in conic(a2,b2,c2,d2,e2,f2) &
      (homography(N)).P5 in conic(a2,b2,c2,d2,e2,f2) &
      (homography(N)).P6 in conic(a2,b2,c2,d2,e2,f2) by A1,A2,A5,Th16;
    end;
    hence thesis;
  end;
