reserve T for TopStruct;
reserve GX for TopSpace;

theorem
  for X9 being SubSpace of T, A being Subset of T, A1 being Subset of X9
  st A = A1 holds Cl A1 = (Cl A) /\ ([#]X9)
proof
  let X9 be SubSpace of T, A be Subset of T, A1 be Subset of X9 such that
A1: A = A1;
  for p being object holds p in Cl A1 iff p in (Cl A) /\ ([#]X9)
  proof
    let p be object;
    thus p in Cl A1 implies p in (Cl A) /\ ([#]X9)
    proof
      reconsider DD = Cl A1 as Subset of T by Th11;
      assume
A2:   p in Cl A1;
A3:   for D1 being Subset of T st D1 is closed holds A c= D1 implies p in D1
      proof
        let D1 be Subset of T such that
A4:     D1 is closed;
        set D3 = D1 /\ [#]X9;
        assume A c= D1;
        then
A5:     A1 c= D1 /\ [#]X9 by A1,XBOOLE_1:19;
        D3 is closed by A4,Th13;
        then p in D3 by A2,A5,Th15;
        hence thesis by XBOOLE_0:def 4;
      end;
      p in DD by A2;
      then p in Cl A by A3,Th15;
      hence thesis by A2,XBOOLE_0:def 4;
    end;
    assume
A6: p in (Cl A) /\ ([#]X9);
    then
A7: p in Cl A by XBOOLE_0:def 4;
    now
      let D1 be Subset of X9;
      assume D1 is closed;
      then consider D2 being Subset of T such that
A8:   D2 is closed and
A9:   D1 = D2 /\ [#]X9 by Th13;
A10:  D2 /\ [#]X9 c= D2 by XBOOLE_1:17;
      assume A1 c= D1;
      then A c= D2 by A1,A9,A10;
      then p in D2 by A7,A8,Th15;
      hence p in D1 by A6,A9,XBOOLE_0:def 4;
    end;
    hence thesis by A6,Th15;
  end;
  hence thesis by TARSKI:2;
end;
