
theorem Th17:
  for m,k be Nat, r be Tuple of (m+2),k-SD st k >= 2 holds SDDec(
  M0(r)) + SDDec(Mmask(r)) = SDDec(r) + SDDec(DecSD(0,m+2,k))
proof
  let m,k be Nat, r be Tuple of (m+2),k-SD;
A1: m + 2 >= 1 by NAT_1:12;
A2: for i be Nat st i in Seg (m+2) holds DigA(M0(r),i) = DigA(r,i) & DigA(
  Mmask(r),i) = 0 or DigA(Mmask(r),i) = DigA(r,i) & DigA(M0(r),i) = 0
  proof
    let i be Nat;
    assume
A3: i in Seg (m+2);
    now
      per cases;
      suppose
A4:     i < m;
A5:     DigA(M0(r),i) = M0Digit(r,i) by A3,Def2
          .= 0 by A3,A4,Def1;
        DigA(Mmask(r),i) = MmaskDigit(r,i) by A3,Def9
          .= r.i by A3,A4,Def8
          .= DigA(r,i) by A3,RADIX_1:def 3;
        hence thesis by A5;
      end;
      suppose
A6:     i >= m;
A7:     DigA(Mmask(r),i) = MmaskDigit(r,i) by A3,Def9
          .= 0 by A3,A6,Def8;
        DigA(M0(r),i) = M0Digit(r,i) by A3,Def2
          .= r.i by A3,A6,Def1
          .= DigA(r,i) by A3,RADIX_1:def 3;
        hence thesis by A7;
      end;
    end;
    hence thesis;
  end;
  assume k >= 2;
  hence thesis by A1,A2,RADIX_5:15;
end;
