reserve R for Ring,
  I for Ideal of R,
  a, b for Element of R;
reserve R for add-associative right_zeroed right_complementable Abelian
    distributive left_unital non empty doubleLoopStr;
reserve I for Ideal of R;
reserve a,b for Element of R;
reserve x, y for Element of R/I;

theorem Th17:
  I is quasi-prime iff R/I is domRing-like
proof
  set E = EqRel(R,I);
A1: Class(E,0.R) = 0.(R/I) by Def6;
  thus I is quasi-prime implies R/I is domRing-like
  proof
    assume
A2: I is quasi-prime;
    let x, y be Element of R/I such that
A3: x*y = 0.(R/I);
    consider a being Element of R such that
A4: x = Class(E,a) by Th11;
    consider b being Element of R such that
A5: y = Class(E,b) by Th11;
    x*y = Class(E,a*b) by A4,A5,Th14;
    then a*b-0.R = a*b & a*b-0.R in I by A1,A3,Th6,RLVECT_1:13;
    then
A6: a in I or b in I by A2;
    a-0.R = a & b-0.R = b by RLVECT_1:13;
    hence thesis by A1,A4,A5,A6,Th6;
  end;
  assume
A7: R/I is domRing-like;
  let a, b be Element of R;
  reconsider x = Class(E,a), y = Class(E,b) as Element of R/I by Th12;
A8: a*b-0.R = a*b by RLVECT_1:13;
A9: Class(E,a*b) = x*y by Th14;
  assume a*b in I;
  then Class(E,a*b) = Class(E,0.R) by A8,Th6;
  then x = 0.(R/I) or y = 0.(R/I) by A1,A7,A9;
  then a-0.R in I or b-0.R in I by A1,Th6;
  hence thesis by RLVECT_1:13;
end;
