reserve L for Ortholattice,
  a, b, c for Element of L;

theorem Th17:
  for a, b being Element of B_6 st a = 3 \ 1 & b = 1 holds a "\/"
  b = 3 & a "/\" b = 0
proof
A1: the carrier of B_6 = { 0, 1, 3 \ 1, 2, 3 \ 2, 3 } by YELLOW_1:1;
  then reconsider z = 3 as Element of B_6 by ENUMSET1:def 4;
A2: Segm 1 c= Segm 3 by NAT_1:39;
  let x,y be Element of B_6;
  assume that
A3: x = 3\1 and
A4: y = 1;
A5: 1 \/ (3\1) = 1 \/ 3 by XBOOLE_1:39
    .= 3 by A2,XBOOLE_1:12;
  now
    thus x <= z & y <= z by A3,YELLOW_1:3,A2,A4;
    let w be Element of B_6;
    assume x <= w & y <= w;
    then x c= w & y c= w by YELLOW_1:3;
    then x \/ y c= w by XBOOLE_1:8;
    hence z <= w by A3,A4,A5,YELLOW_1:3;
  end;
  hence x "\/" y = 3 by YELLOW_0:22;
  reconsider z = 0 as Element of B_6 by A1,ENUMSET1:def 4;
  x misses y by A3,A4,XBOOLE_1:79;
  then
A6: x /\ y = 0 by XBOOLE_0:def 7;
  now
    z c= x & z c= y;
    hence z <= x & z <= y by YELLOW_1:3;
    let w be Element of B_6;
    assume w <= x & w <= y;
    then w c= x & w c= y by YELLOW_1:3;
    then w c= x /\ y by XBOOLE_1:19;
    hence w <= z by A6;
  end;
  hence thesis by YELLOW_0:23;
end;
