reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th17:
  Y is finite & (for P being Subset of T st P in Y holds P is
  bounded) implies union Y is bounded
proof
  assume that
A1: Y is finite and
A2: for P being Subset of T st P in Y holds P is bounded;
  defpred P[set] means ex X being Subset of T st X = union $1 & X is bounded;
A3: for x,B being set st x in Y & B c= Y & P[B] holds P[B \/ {x}]
  proof
    let x,B be set such that
A4: x in Y and
    B c= Y and
A5: P[B];
    consider X being Subset of T such that
A6: X = union B & X is bounded by A5;
    reconsider x as Subset of T by A4;
A7: union (B \/ {x}) = union B \/ union {x} by ZFMISC_1:78
      .= union B \/ x by ZFMISC_1:25;
A8: x is bounded by A2,A4;
    ex Y being Subset of T st Y = union (B \/ {x}) & Y is bounded
    proof
      take X \/ x;
      thus thesis by A6,A7,A8,Th13;
    end;
    hence thesis;
  end;
A9: P[{}]
  proof
    set m = {}T;
    m = union {} by ZFMISC_1:2;
    hence thesis;
  end;
  P[Y] from FINSET_1:sch 2(A1,A9,A3);
  hence thesis;
end;
