reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th17:
  for T being set, F being Subset-Family of T holds F is
  closed_for_countable_meets compl-closed iff F is closed_for_countable_unions
  compl-closed
proof
  let T be set, F be Subset-Family of T;
  hereby
    assume
A1: F is closed_for_countable_meets compl-closed;
    for G being countable Subset-Family of T st G c= F holds union G in F
    proof
      let G be countable Subset-Family of T;
      assume
A2:   G c= F;
      per cases;
      suppose
        G = {};
        hence thesis by A1,A2,SETFAM_1:1,ZFMISC_1:2;
      end;
      suppose
        G <> {};
        then reconsider G9 = G as non empty Subset-Family of T;
        COMPLEMENT G9 c= F & COMPLEMENT G9 is countable by A1,A2,Th1,Th16;
        then
A3:     meet COMPLEMENT G9 in F by A1;
        (meet COMPLEMENT G9)` = (union G9)`` by TOPS_2:6
          .= union G9;
        hence thesis by A1,A3;
      end;
    end;
    hence F is closed_for_countable_unions compl-closed by A1;
  end;
  assume
A4: F is closed_for_countable_unions compl-closed;
  for G being countable Subset-Family of T st G c= F holds meet G in F
  proof
    let G be countable Subset-Family of T;
    assume
A5: G c= F;
    per cases;
    suppose
      G = {};
      hence thesis by A4,A5,SETFAM_1:1,ZFMISC_1:2;
    end;
    suppose
      G <> {};
      then reconsider G9 = G as non empty Subset-Family of T;
      COMPLEMENT G9 c= F & COMPLEMENT G9 is countable by A4,A5,Th1,Th16;
      then
A6:   union COMPLEMENT G9 in F by A4;
      (union COMPLEMENT G9)` = (meet G9)`` by TOPS_2:7
        .= meet G9;
      hence thesis by A4,A6;
    end;
  end;
  hence thesis by A4;
end;
