reserve
  x for object, X for set,
  i, n, m for Nat,
  r, s for Real,
  c, c1, c2, d for Complex,
  f, g for complex-valued Function,
  g1 for n-element complex-valued FinSequence,
  f1 for n-element real-valued FinSequence,
  T for non empty TopSpace,
  p for Element of TOP-REAL n;

theorem Th17:
  (g1+*(i,c)) - g1 = (0*n)+*(i,c-(g1.i))
  proof
A1: dom (g1+*(i,c) - g1) = dom (g1+*(i,c)) /\ dom g1 by VALUED_1:12;
A2: dom (0*n) = Seg n;
A3: dom g1 = Seg n by FINSEQ_1:89;
A4: dom (g1+*(i,c)) = dom g1 by FUNCT_7:30;
    hence dom (g1+*(i,c) - g1) = dom ((0*n)+*(i,c-(g1.i)))
     by A1,A3,FINSEQ_1:89;
    let x be object;
    assume
A5: x in dom (g1+*(i,c) - g1);
    then
A6: (g1+*(i,c) - g1).x = (g1+*(i,c)).x - g1.x by VALUED_1:13;
    per cases;
    suppose
A7:   x = i;
      hence (g1+*(i,c) - g1).x = c - g1.x by A6,A1,A5,A4,FUNCT_7:31
      .= ((0*n)+*(i,c-(g1.i))).x by A1,A2,A3,A5,A4,A7,FUNCT_7:31;
    end;
    suppose
A8:   x <> i;
      hence (g1+*(i,c) - g1).x = g1.x - g1.x by A6,FUNCT_7:32
      .= (n|->0).x
      .= ((0*n)+*(i,c-(g1.i))).x by A8,FUNCT_7:32;
    end;
  end;
