reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem
  for R being complete LATTICE, N being net of R, p,q being Element of R
  st p is_S-limit_of N & N is_eventually_in downarrow q holds p <= q
proof
  let R be complete LATTICE, N be net of R, p,q be Element of R such that
A1: p <= lim_inf N and
A2: N is_eventually_in downarrow q;
  consider j0 being Element of N such that
A3: for i being Element of N st j0 <= i holds N.i in downarrow q
  by A2;
  set X = the set of all "/\"({N.i where i is Element of N:
  i >= j},R) where j is Element of N;
  reconsider q9= q as Element of R;
  q9 is_>=_than X
  proof
    let x be Element of R;
    assume x in X;
    then consider j1 being Element of N such that
A4: x = "/\"({N.i where i is Element of N: i >= j1},R);
    set Y = {N.i where i is Element of N: i >= j1};
    reconsider j1 as Element of N;
    consider j2 being Element of N such that
A5: j2 >= j0 and
A6: j2 >= j1 by YELLOW_6:def 3;
    N.j2 in Y by A6;
    then
A7: x <= N.j2 by A4,YELLOW_2:22;
    N.j2 in downarrow q by A3,A5;
    then N.j2 <= q9 by WAYBEL_0:17;
    hence x <= q9 by A7,YELLOW_0:def 2;
  end;
  then lim_inf N <= q9 by YELLOW_0:32;
  hence thesis by A1,YELLOW_0:def 2;
end;
