 reserve x, y, y1, y2 for set;
 reserve V for Z_Module;
 reserve u, v, w for Vector of V;
 reserve F, G, H, I for FinSequence of V;
 reserve W, W1, W2, W3 for Submodule of V;
 reserve KL1, KL2 for Linear_Combination of V;
 reserve X for Subset of V;

theorem Th17:
  for V being Z_Module
  for A being Subset of V st A is linearly-independent
  for v being Vector of V st v in A for B being Subset of V st B = A \ {v}
  holds not v in Lin(B)
  proof
    let V be Z_Module;
    let A be Subset of V such that
    A1: A is linearly-independent;
    let v be Vector of V;
    assume v in A; then
    A2: {v} is Subset of A by SUBSET_1:41;
    v in {v} by TARSKI:def 1;
    then v in Lin({v}) by ZMODUL02:65;
    then consider K being Linear_Combination of {v} such that
    A3: v = Sum(K) by ZMODUL02:64;
    let B be Subset of V such that
    A4: B = A \ {v};
    B c= A by A4,XBOOLE_1:36;
    then
    A5: B \/ {v} c= A \/ A by A2,XBOOLE_1:13;
    assume v in Lin(B);
    then consider L being Linear_Combination of B such that
    A6: v = Sum(L) by ZMODUL02:64;
    A7: Carrier(L) c= B & Carrier(K) c= {v} by VECTSP_6:def 4;
    then Carrier(L) \/ Carrier(K) c= B \/ {v} by XBOOLE_1:13;
    then Carrier(L - K) c= Carrier(L) \/ Carrier(K) & Carrier(L) \/ Carrier(K)
    c= A by A5,ZMODUL02:40;
    then
    A8: L - K is Linear_Combination of A by XBOOLE_1:1,VECTSP_6:def 4;
    A9: for x being Vector of V holds x in Carrier(L) implies K.x = 0
    proof
      let x be Vector of V;
      assume x in Carrier(L);
      then not x in Carrier(K) by A4,A7,XBOOLE_0:def 5;
      hence thesis;
    end;
    A10:
    now
      let x be set such that
      A11: x in Carrier(L) and
      A12: not x in Carrier(L - K);
      reconsider x as Vector of V by A11;
      A13: L.x <> 0 by A11,ZMODUL02:8;
      (L - K).x = L.x - K.x by ZMODUL02:39
      .= L.x - 0.INT.Ring by A9,A11
      .= L.x;
      hence contradiction by A12,A13;
    end;
    v <> 0.V by A1,A2,ZMODUL02:56;
    then Carrier(L) is non empty by A6,ZMODUL02:23;
    then ex w being object st w in Carrier(L) by XBOOLE_0:def 1;
    then
    A14: Carrier(L - K) is non empty by A10;
    0.V = Sum(L) + (- Sum(K)) by A6,A3,RLVECT_1:5
    .= Sum(L) + Sum(-K) by ZMODUL02:54
    .= Sum(L - K) by ZMODUL02:52;
    hence contradiction by A1,A8,A14;
  end;
