
theorem Th18:
  for X, Y being compact non empty TopSpace, R being Subset-Family
of X, F being Subset-Family of [:Y, X:] st F is Cover of [:Y, X:] & F is open &
R = { Q where Q is open Subset of X : ex FQ being Subset-Family of [:Y, X:] st
FQ c= F & FQ is finite & [:[#]Y, Q:] c= union FQ } holds R is open & R is Cover
  of X
proof
  let X, Y be compact non empty TopSpace, R be Subset-Family of X, F be
  Subset-Family of [:Y, X:];
  assume that
A1: F is Cover of [:Y, X:] and
A2: F is open and
A3: R = { Q where Q is open Subset of X : ex FQ being Subset-Family of
  [:Y, X:] st FQ c= F & FQ is finite & [:[#]Y, Q:] c= union FQ };
  now
    let P be Subset of X;
    assume P in R;
    then
    ex E being open Subset of X st E = P & ex FQ being Subset-Family of [:Y
    , X:] st FQ c= F & FQ is finite & [: [#]Y, E:] c= union FQ by A3;
    hence P is open;
  end;
  hence R is open;
A4: union F = [#] [:Y, X:] by A1,SETFAM_1:45;
  [#]X c= union R
  proof
    let k be object;
    assume k in [#]X;
    then reconsider k9 = k as Point of X;
    reconsider Z = [:[#]Y, {k9}:] as Subset of [:Y, X:];
    F is Cover of Z & Z is compact by A4,Th16,SETFAM_1:def 11;
    then consider G being Subset-Family of [:Y, X:] such that
A5: G c= F and
A6: G is Cover of Z and
A7: G is finite by A2;
    set uR = union G;
    set Q = { x where x is Point of X : [:[#]Y, {x}:] c= uR };
    Q c= the carrier of X
    proof
      let k be object;
      assume k in Q;
      then ex x1 being Point of X st k = x1 & [:[#]Y, {x1}:] c= uR;
      hence thesis;
    end;
    then reconsider Q as Subset of X;
    Z c= union G by A6,SETFAM_1:def 11;
    then
A8: k9 in Q;
A9: ex FQ being Subset-Family of [:Y, X:] st FQ c= F & FQ is finite & [:
    [#]Y, Q:] c= union FQ
    proof
      take G;
      [:[#]Y, Q:] c= union G
      proof
        let z be object;
        assume z in [:[#]Y, Q:];
        then consider x1, x2 be object such that
A10:    x1 in [#]Y and
A11:    x2 in Q and
A12:    z = [x1, x2] by ZFMISC_1:def 2;
        consider x29 being Point of X such that
A13:    x29 = x2 and
A14:    [:[#]Y, {x29}:] c= uR by A11;
        x2 in {x29} by A13,TARSKI:def 1;
        then z in [:[#]Y, {x29}:] by A10,A12,ZFMISC_1:87;
        hence thesis by A14;
      end;
      hence thesis by A5,A7;
    end;
    uR is open by A2,A5,TOPS_2:11,19;
    then Q in the topology of X by Th12;
    then Q is open by PRE_TOPC:def 2;
    then Q in R by A3,A9;
    hence thesis by A8,TARSKI:def 4;
  end;
  hence thesis by SETFAM_1:def 11;
end;
