reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for z,u being Element of Y, h being Function st G is independent & G={
  A,B,C,D} & A<>B & A<>C & A<>D & B<>C & B<>D & C<>D holds EqClass(u,B '/\' C
  '/\' D) meets EqClass(z,A)
proof
  let z,u be Element of Y;
  let h be Function;
  assume that
A1: G is independent and
A2: G={A,B,C,D} and
A3: A<>B & A<>C & A<>D & B<>C & B<>D & C<>D;
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
  D)) +* (A .--> EqClass(z,A));
A4: h.B = EqClass(u,B) by A3,Th15;
A5: h.D = EqClass(u,D) by A3,Th15;
A6: h.C = EqClass(u,C) by A3,Th15;
A7: rng h = {h.A,h.B,h.C,h.D} by A2,Th17;
  rng h c= bool Y
  proof
    let t be object;
    assume
A8: t in rng h;
    per cases by A7,A8,ENUMSET1:def 2;
    suppose
      t=h.A;
      then t=EqClass(z,A) by FUNCT_7:94;
      hence thesis;
    end;
    suppose
      t=h.B;
      hence thesis by A4;
    end;
    suppose
      t=h.C;
      hence thesis by A6;
    end;
    suppose
      t=h.D;
      hence thesis by A5;
    end;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A9: dom h = G by A2,Th16;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A10: d in G;
    per cases by A2,A10,ENUMSET1:def 2;
    suppose
A11:  d=A;
      h.A=EqClass(z,A) by FUNCT_7:94;
      hence thesis by A11;
    end;
    suppose
A12:  d=B;
      h.B=EqClass(u,B) by A3,Th15;
      hence thesis by A12;
    end;
    suppose
A13:  d=C;
      h.C=EqClass(u,C) by A3,Th15;
      hence thesis by A13;
    end;
    suppose
A14:  d=D;
      h.D=EqClass(u,D) by A3,Th15;
      hence thesis by A14;
    end;
  end;
  then Intersect FF <>{} by A1,A9,BVFUNC_2:def 5;
  then consider m being object such that
A15: m in Intersect FF by XBOOLE_0:def 1;
  A in dom h by A2,A9,ENUMSET1:def 2;
  then
A16: h.A in rng h by FUNCT_1:def 3;
  then
A17: m in meet FF by A15,SETFAM_1:def 9;
  D in dom h by A2,A9,ENUMSET1:def 2;
  then h.D in rng h by FUNCT_1:def 3;
  then
A18: m in h.D by A17,SETFAM_1:def 1;
  C in dom h by A2,A9,ENUMSET1:def 2;
  then h.C in rng h by FUNCT_1:def 3;
  then
A19: m in h.C by A17,SETFAM_1:def 1;
  B in dom h by A2,A9,ENUMSET1:def 2;
  then h.B in rng h by FUNCT_1:def 3;
  then m in h.B by A17,SETFAM_1:def 1;
  then m in EqClass(u,B) /\ EqClass(u,C) by A4,A6,A19,XBOOLE_0:def 4;
  then
A20: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A5,A18,XBOOLE_0:def 4
;
  h.A = EqClass(z,A) & m in h.A by A16,A17,FUNCT_7:94,SETFAM_1:def 1;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(z,A) by A20
,XBOOLE_0:def 4;
  then
A21: EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) meets EqClass(z,A) by
XBOOLE_0:4;
  EqClass(u,B '/\' C '/\' D) = EqClass(u,B '/\' C) /\ EqClass(u,D) by Th1;
  hence thesis by A21,Th1;
end;
