reserve IIG for monotonic Circuit-like non void non empty ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve s for State of SCS;
reserve iv for InputValues of SCS;
reserve IIG for finite monotonic Circuit-like non void non empty
  ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve InpFs for InputFuncs of SCS;
reserve s for State of SCS;
reserve iv for InputValues of SCS;

theorem
  commute InpFs is constant & InputVertices IIG is non empty implies for
s being State of SCS, n be Element of NAT st n = depth SCS holds (Computation(s
  ,InpFs)).n is stable
proof
  assume that
A1: commute InpFs is constant and
A2: InputVertices IIG is non empty;
A3: dom commute InpFs = NAT by A2,PRE_CIRC:5;
A4: IIG is with_input_V by A2;
  then reconsider iv = (commute InpFs).0 as InputValues of SCS by CIRCUIT1:2;
  let s be State of SCS, n be Element of NAT such that
A5: n = depth SCS;
  reconsider Cn = (Computation(s,InpFs)).n as State of SCS;
A6: iv c= Cn by A1,A2,Th14;
A7: (n+1)-th_InputValues InpFs = (commute InpFs).(n+1) by A4,CIRCUIT1:def 2
    .= (commute InpFs).0 by A1,A3,FUNCT_1:def 10;
  reconsider Cn1 = (Computation(s,InpFs)).(n+1) as State of SCS;
  now
    thus the carrier of IIG = dom Cn by CIRCUIT1:3;
    thus the carrier of IIG = dom Cn1 by CIRCUIT1:3;
    let x be object;
    assume x in the carrier of IIG;
    then reconsider x9 = x as Vertex of IIG;
A8: depth(x9,SCS) <= n by A5,CIRCUIT1:17;
    then Cn.x9 = IGValue(x9,iv) by A1,A2,Th16;
    hence Cn.x = Cn1.x by A1,A2,A8,Th16,NAT_1:12;
  end;
  hence (Computation(s,InpFs)).n = (Computation(s,InpFs)).(n+1)
    .= Following(Cn,(n+1)-th_InputValues InpFs) by Def9
    .= Following((Computation(s,InpFs)).n) by A7,A6,FUNCT_4:98;
end;
