
theorem Th16:
  for z being Complex holds Arg z in ].0,PI.[ iff Im z > 0
proof
  let z be Complex;
  thus Arg z in ].0,PI.[ implies Im z > 0
  proof
    assume Arg z in ].0,PI.[;
    then
A1: 0<Arg(z) & Arg(z)<PI by XXREAL_1:4;
A2: Arg(z)<PI/2 or Arg(z)=PI/2 or Arg(z)>PI/2 by XXREAL_0:1;
    now
      per cases by A1,A2,XXREAL_1:4;
      case
        Arg(z) in ].0,PI/2.[;
        hence thesis by COMPTRIG:41;
      end;
      case
        Arg(z)=PI/2;
        hence thesis by COMPTRIG:48,SIN_COS:77;
      end;
      case
        Arg(z) in ].PI/2,PI.[;
        hence thesis by COMPTRIG:42;
      end;
    end;
    hence thesis;
  end;
A3: ].PI/2,PI.[ c= ].0,PI.[ by COMPTRIG:5,XXREAL_1:46;
A4: ].0,PI/2.[ c= ].0,PI.[ by COMPTRIG:5,XXREAL_1:46;
  thus Im z > 0 implies Arg z in ].0,PI.[
  proof
    assume
A5: Im z >0;
    now
      per cases;
      case
        Re z>0;
        then Arg(z) in ].0,PI/2.[ by A5,COMPTRIG:41;
        hence thesis by A4;
      end;
      case
        Re z=0;
        then z= 0 + (Im z)*<i> by COMPLEX1:13;
        then Arg(z)=PI/2 by A5,COMPTRIG:37;
        hence thesis by COMPTRIG:5,XXREAL_1:4;
      end;
      case
        Re z<0;
        then Arg z in ].PI/2,PI.[ by A5,COMPTRIG:42;
        hence thesis by A3;
      end;
    end;
    hence thesis;
  end;
end;
