reserve Rseq, Rseq1, Rseq2 for Function of [:NAT,NAT:],REAL;
reserve rseq1,rseq2 for convergent Real_Sequence;
reserve n,m,N,M for Nat;
reserve e,r for Real;
reserve Pseq for P-convergent Function of [:NAT,NAT:],REAL;

theorem
for Rseq1 be subsequence of Rseq st
 Rseq is convergent_in_cod1 & lim_in_cod1 Rseq is convergent holds
   lim_in_cod1 Rseq1 is convergent &
   cod1_major_iterated_lim Rseq1 = cod1_major_iterated_lim Rseq
proof
   let Rseq1 be subsequence of Rseq;
   assume that
a1: Rseq is convergent_in_cod1 & lim_in_cod1 Rseq is convergent;
   consider I1,I2 be increasing sequence of NAT such that
a7: for n,m be Nat holds Rseq1.(n,m) = Rseq.(I1.n,I2.m) by def9;
a8:Rseq1 is convergent_in_cod1 by a1;
a10:for e st 0<e
    ex N st for m st m >= N holds
       |.(lim_in_cod1 Rseq1).m - cod1_major_iterated_lim Rseq.| < e
   proof
    let e;
    assume 0<e; then
    consider N such that
a11: for m st m >= N holds
      |.(lim_in_cod1 Rseq).m - cod1_major_iterated_lim Rseq.| < e by a1,def34;
    take N;
    hereby let m;
     assume a12: m >= N;
     reconsider m2 = I2.m as Element of NAT;
     reconsider m1 = m as Element of NAT by ORDINAL1:def 12;
x2:  ProjMap2(Rseq1,m1) is convergent by a8;
     for p be Real st 0<p
      ex K be Nat st
       for n be Nat st n>=K holds
        |.ProjMap2(Rseq1,m1).n - lim ProjMap2(Rseq,m2).| < p
     proof
      let p be Real;
      assume b1: 0<p;
      ProjMap2(Rseq,m2) is convergent by a1; then
      consider K be Nat such that
b2:    for n st n>=K holds |.ProjMap2(Rseq,m2).n - lim ProjMap2(Rseq,m2).| < p
          by b1,SEQ_2:def 7;
      take K;
      hereby let n;
       assume b3: n >= K;
x2:    n is Element of NAT &
       I1.n is Element of NAT & I2.m is Element of NAT by ORDINAL1:def 12;
       I1.n >= n by lem01; then
       I1.n >= K by b3,XXREAL_0:2; then
       |.ProjMap2(Rseq,m2).(I1.n)-lim ProjMap2(Rseq,m2).| < p by b2; then
       |. Rseq.(I1.n,I2.m)-lim ProjMap2(Rseq,m2).| <p
         by MESFUNC9:def 7; then
       |. Rseq1.(n,m) - lim ProjMap2(Rseq,m2).| < p by a7;
       hence |. ProjMap2(Rseq1,m1).n - lim ProjMap2(Rseq,m2).| <p
         by x2,MESFUNC9:def 7;
      end;
     end; then
c1:  lim ProjMap2(Rseq1,m1) = lim ProjMap2(Rseq,m2) by x2,SEQ_2:def 7;
     I2.m >= m by lem01; then
     I2.m >= N by a12,XXREAL_0:2; then
a13: |.(lim_in_cod1 Rseq).(I2.m) - cod1_major_iterated_lim Rseq.| < e by a11;
     (lim_in_cod1 Rseq).(I2.m) = lim ProjMap2(Rseq,m2) by def32;
     hence |.(lim_in_cod1 Rseq1).m - cod1_major_iterated_lim Rseq.| < e
       by def32,a13,c1;
    end;
   end;
   hence lim_in_cod1 Rseq1 is convergent by SEQ_2:def 6;
   hence thesis by a10,def34;
end;
