reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (ln(#)exp_R) implies ln(#)exp_R is_differentiable_on Z & for
  x st x in Z holds ((ln(#)exp_R)`|Z).x = exp_R.x/x + ln.x*exp_R.x
proof
A1: for x st x in Z holds exp_R is_differentiable_in x by SIN_COS:65;
  assume
A2: Z c= dom (ln(#)exp_R);
  then
A3: Z c= dom ln /\ dom exp_Rby VALUED_1:def 4;
  then Z c= dom exp_R by XBOOLE_1:18;
  then
A4: exp_R is_differentiable_on Z by A1,FDIFF_1:9;
A5: Z c= dom ln by A3,XBOOLE_1:18;
A6: for x st x in Z holds x>0
  proof
    let x;
    assume x in Z;
    then x in right_open_halfline(0) by A5,TAYLOR_1:18;
    then x in {g where g is Real: 0<g} by XXREAL_1:230;
    then ex g being Real st x=g & 0<g;
    hence thesis;
  end;
  then for x st x in Z holds ln is_differentiable_in x by TAYLOR_1:18;
  then
A7: ln is_differentiable_on Z by A5,FDIFF_1:9;
A8: for x st x in Z holds diff(ln,x) = 1/x
  proof
    let x;
    assume x in Z;
    then x>0 by A6;
    then x in {g where g is Real: 0<g};
    then x in right_open_halfline(0) by XXREAL_1:230;
    hence thesis by TAYLOR_1:18;
  end;
  for x st x in Z holds ((ln(#)exp_R)`|Z).x = exp_R.x/x + ln.x*exp_R.x
  proof
    let x;
    assume
A9: x in Z;
    then
    ((ln(#)exp_R)`|Z).x = exp_R.x*diff(ln,x)+ln.x*diff(exp_R,x) by A2,A7,A4,
FDIFF_1:21
      .=exp_R.x*(1/x) + ln.x*diff(exp_R,x) by A8,A9
      .=exp_R.x*(1/x) + ln.x*exp_R.x by SIN_COS:65;
    hence thesis;
  end;
  hence thesis by A2,A7,A4,FDIFF_1:21;
end;
