reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (ln*tan) implies ln*tan is_differentiable_on Z & for x st x
  in Z holds ((ln*tan)`|Z).x = 1/(cos.x*sin.x)
proof
  assume
A1: Z c= dom (ln*tan);
A2: for x st x in Z holds tan.x>0
  proof
    let x;
    assume x in Z;
    then tan.x in right_open_halfline(0) by A1,FUNCT_1:11,TAYLOR_1:18;
    then ex g being Real st tan.x=g & 0<g by Lm1;
    hence thesis;
  end;
  dom (ln*tan) c= dom tan by RELAT_1:25;
  then
A3: Z c= dom tan by A1,XBOOLE_1:1;
A4: for x st x in Z holds cos.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom (sin/cos) by A1,FUNCT_1:11;
    hence thesis by Th1;
  end;
A5: for x st x in Z holds tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A4;
    hence thesis by FDIFF_7:46;
  end;
A6: for x st x in Z holds ln*tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then tan is_differentiable_in x & tan.x>0 by A2,A5;
    hence thesis by TAYLOR_1:20;
  end;
  then
A7: ln*tan is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((ln*tan)`|Z).x =1/(cos.x*sin.x)
  proof
    let x;
    assume
A8: x in Z;
    then
A9: cos.x<>0 by A4;
    tan is_differentiable_in x & tan.x>0 by A2,A5,A8;
    then diff(ln*tan,x) =diff(tan,x)/(tan.x) by TAYLOR_1:20
      .=(1/(cos.x)^2)/(tan.x) by A9,FDIFF_7:46
      .=1/((cos.x)^2*tan.x) by XCMPLX_1:78
      .=1/((cos.x)^2*(sin.x/cos.x)) by A3,A8,RFUNCT_1:def 1
      .=1/(((cos.x)^2*sin.x)/cos.x)
      .=cos.x/((cos.x)^2*sin.x) by XCMPLX_1:57
      .=cos.x/(cos.x)^2/sin.x by XCMPLX_1:78
      .=cos.x/cos.x/cos.x/sin.x by XCMPLX_1:78
      .=1/cos.x/sin.x by A4,A8,XCMPLX_1:60
      .=1/(cos.x*sin.x) by XCMPLX_1:78;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A6,FDIFF_1:9;
end;
