reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (ln*sec) implies ln*sec is_differentiable_on Z & for x st x
  in Z holds ((ln*sec)`|Z).x = sin.x/cos.x
proof
  assume
A1: Z c= dom (ln*sec);
A2: for x st x in Z holds sec.x>0
  proof
    let x;
    assume x in Z;
    then sec.x in right_open_halfline(0) by A1,FUNCT_1:11,TAYLOR_1:18;
    then ex g being Real st sec.x=g & 0<g by Lm1;
    hence thesis;
  end;
  dom (ln*sec) c= dom sec by RELAT_1:25;
  then
A3: Z c= dom sec by A1,XBOOLE_1:1;
A4: for x st x in Z holds cos.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom sec by A1,FUNCT_1:11;
    hence thesis by RFUNCT_1:3;
  end;
A5: for x st x in Z holds sec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A4;
    hence thesis by Th1;
  end;
A6: for x st x in Z holds ln*sec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sec is_differentiable_in x & sec.x>0 by A2,A5;
    hence thesis by TAYLOR_1:20;
  end;
  then
A7: ln*sec is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((ln*sec)`|Z).x = sin.x/cos.x
  proof
    let x;
    assume
A8: x in Z;
    then
A9: cos.x<>0 by A4;
    sec is_differentiable_in x & sec.x>0 by A2,A5,A8;
    then diff(ln*sec,x) =diff(sec,x)/(sec.x) by TAYLOR_1:20
      .=(sin.x/(cos.x)^2)/(sec.x) by A9,Th1
      .=(sin.x/(cos.x)^2)/(cos.x)" by A3,A8,RFUNCT_1:def 2
      .=(sin.x*cos.x)/(cos.x*cos.x)
      .=sin.x/cos.x by A4,A8,XCMPLX_1:91;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A6,FDIFF_1:9;
end;
