
theorem alg3a:
for f being ascending Field-yielding sequence
for X being finite Subset of (SeqField f)
ex i being Element of NAT st X c= the carrier of (f.i)
proof
let f be ascending Field-yielding sequence,
    X be finite Subset of (SeqField f);
defpred P[Nat] means
  for X being finite Subset of (SeqField f) st card X = $1
  ex i being Element of NAT st X c= the carrier of f.i;
set F = SeqField f;
H: the carrier of F = Carrier f by dsf
    .= union(the set of all the carrier of f.i where i is Element of NAT);
IA: P[0]
    proof
    now let X be finite Subset of (SeqField f);
      assume card X = 0; then
      X c= the carrier of f.0;
      hence ex i being Element of NAT st X c= the carrier of f.i;
      end;
    hence thesis;
    end;
I1: P[1]
    proof
    now let X be finite Subset of (SeqField f);
      assume card X = 1; then
      consider a being object such that A: X = {a} by CARD_2:42;
      a in X by A,TARSKI:def 1; then
      reconsider a as Element of F;
      consider Y being set such that
      B: a in Y &
         Y in the set of all the carrier of f.i where i is Element of NAT
         by H,TARSKI:def 4;
      consider i being Element of NAT such that
      C: Y = the carrier of f.i by B;
      X c= the carrier of f.i by A,B,C,TARSKI:def 1;
      hence ex i being Element of NAT st X c= the carrier of f.i;
      end;
    hence thesis;
    end;
IS: now let k be Nat;
    assume IV: P[k];
    now let X be finite Subset of (SeqField f);
      assume AS: card X = k + 1; then
      A: X <> {};
      set a = the Element of X;
      A1: a in X by A; then
      reconsider a as Element of F;
      set X1 = X \ {a};
      a in {a} by TARSKI:def 1; then
      not a in X1 by XBOOLE_0:def 5; then
      B: card (X1 \/ {a}) = card X1 + 1 by CARD_2:41;
      {a} c= X by A1,TARSKI:def 1; then
      C: X1 \/ {a} = X by FIELD_5:1; then
      consider i1 being Element of NAT such that
      D: X1 c= the carrier of f.i1 by AS,B,IV;
      card {a} = 1 by CARD_2:42; then
      consider i2 being Element of NAT such that
      E: {a} c= the carrier of f.i2 by I1;
      a in {a} by TARSKI:def 1; then
      reconsider a as Element of f.i2 by E;
      per cases;
      suppose i1 <= i2; then
        f.i2 is FieldExtension of f.i1 by lem3; then
        f.i1 is Subfield of f.i2 by FIELD_4:7; then
        the carrier of f.i1 c= the carrier of f.i2 by EC_PF_1:def 1; then
        X1 c= the carrier of f.i2 by D; then
        X1 \/ {a} c= (the carrier of f.i2) \/ (the carrier of f.i2)
           by XBOOLE_1:13;
        hence ex i being Element of NAT st X c= the carrier of f.i by C;
        end;
      suppose i2 <= i1; then
        reconsider a as Element of f.i1 by lem1;
        X1 \/ {a} c= (the carrier of f.i1) \/ (the carrier of f.i1)
           by D,XBOOLE_1:13;
        hence ex i being Element of NAT st X c= the carrier of f.i by C;
        end;
      end;
    hence P[k+1];
    end;
I: for k being Nat holds P[k] from NAT_1:sch 2(IA,IS);
consider n being Nat such that I2: card X = n;
consider i being Element of NAT such that
H: X c= the carrier of f.i by I,I2;
thus thesis by H;
end;
