reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem
  for A being Subset of FT st FT is filled connected & A <> {} & A` <>
  {} holds A^delta <>{}
proof
  let A be Subset of FT;
  assume that
A1: FT is filled connected and
A2: A <> {} & A` <>{};
A3: now
    assume A^b meets A`;
    then consider x being object such that
A4: x in A^b and
A5: x in A` by XBOOLE_0:3;
    reconsider x as Element of FT by A4;
    x in U_FT x by A1;
    then
A6: U_FT x meets A` by A5,XBOOLE_0:3;
    U_FT x meets A by A4,FIN_TOPO:8;
    hence ex z being Element of FT st U_FT z meets A & U_FT z meets A` by A6;
  end;
A7: now
    assume A meets (A`)^b;
    then consider x being object such that
A8: x in (A`)^b and
A9: x in A by XBOOLE_0:3;
    reconsider x as Element of FT by A8;
    x in U_FT x by A1;
    then
A10: U_FT x meets A by A9,XBOOLE_0:3;
    U_FT x meets A` by A8,FIN_TOPO:8;
    hence ex z being Element of FT st U_FT z meets A & U_FT z meets A` by A10;
  end;
  {}={}FT & A \/ A` = [#]FT by XBOOLE_1:45;
  then not A,A` are_separated by A1,A2,Th4,XBOOLE_1:79;
  hence thesis by A3,A7,FINTOPO4:def 1,FIN_TOPO:5;
end;
