
theorem Th20:
  for A be non empty closed_interval Subset of REAL,
    rho be Function of A,REAL,
    u be PartFunc of REAL,REAL
  st rho is bounded_variation
   & dom u = A
   & u|A is uniformly_continuous
  holds
    for T being DivSequence of A, S be middle_volume_Sequence of rho,u,T
     st delta T is convergent & lim delta T = 0
    holds middle_sum(S) is convergent
  proof
    let A be non empty closed_interval Subset of REAL,
        rho be Function of A,REAL,
        u be PartFunc of REAL,REAL;
    assume that
    A1: rho is bounded_variation & dom u = A and
    A2: u|A is uniformly_continuous;
    thus
      for T being DivSequence of A, S be middle_volume_Sequence of rho,u,T
        st delta T is convergent & lim delta T = 0
          holds middle_sum(S) is convergent
    proof
      let T being DivSequence of A, S be middle_volume_Sequence of rho,u,T;
      assume
      A4: delta T is convergent & lim delta T = 0;
      defpred P[Element of NAT, set] means
      ex p being FinSequence of REAL
      st p = $2 & len p = len (T.$1) & for i be Nat st i in dom (T.$1)
      holds
      (p.i) in dom (u|divset((T.$1),i))
      & ex z be Real
        st z = (u|divset((T.$1),i)).(p.i)
         & (S.$1).i = z * (vol (divset((T.$1),i),rho));
      A5: for k be Element of NAT ex p be Element of (REAL)* st P[k, p]
      proof
        let k be Element of NAT;
        defpred P1[Nat,set] means
        $2 in dom (u|divset((T.k),$1)) &
        ex c be Real st c = (u|divset((T.k),$1)).($2) &
        (S.k).$1 = c * (vol (divset((T.k),$1),rho));
        A6: Seg len(T.k) = dom(T.k) by FINSEQ_1:def 3;
        A7: for i be Nat st i in Seg len (T.k)
            ex x be Element of REAL st P1[i,x]
        proof
          let i be Nat;
          assume i in Seg len(T.k); then
          i in dom (T.k) by FINSEQ_1:def 3; then
          consider c be Real such that
          A8: c in rng (u|divset((T.k),i)) &
          (S.k).i = c * (vol(divset((T.k),i),rho)) by A1,INTEGR22:def 5;
          consider x be object such that
          A9: x in dom (u|divset(T.k,i)) &
          c = (u|divset(T.k,i)).x by A8,FUNCT_1:def 3;
          reconsider x as Element of REAL by A9;
          take x;
          thus thesis by A8,A9;
        end;
        consider p be FinSequence of REAL such that
        A10: dom p = Seg len(T.k)
          & for i be Nat st i in Seg len(T.k) holds P1[i,p.i]
            from FINSEQ_1:sch 5(A7);
        take p;
        len p = len (T.k) by A10,FINSEQ_1:def 3;
        hence thesis by A6,A10,FINSEQ_1:def 11;
      end;
      consider Fn be sequence of (REAL)* such that
      A11: for x be Element of NAT holds P[x, Fn.x] from FUNCT_2:sch 3(A5);
      consider Fm be sequence of (REAL)* such that
      A12: for x be Element of NAT holds P[x, Fm.x] from FUNCT_2:sch 3(A5);
      set TVD = total_vd(rho);
      A13: 0 <= TVD by A1,INTEGR22:6;
      now
        let p be Real;
        set pp2= p/2;
        set pv = pp2 / (TVD + 1);
        assume
        B13: p > 0; then
        A14: 0 < pp2 & pp2 < p by XREAL_1:215,216; then
        A15: 0 < pv by A13,XREAL_1:139; then
        pv*(TVD) < pv *(TVD + 1) by XREAL_1:29,68; then
        pv*(TVD) < pp2 by A13,XCMPLX_1:87; then
        A16: pv*(TVD) < p by A14,XXREAL_0:2;
        set p2v = pv/2;
        consider sk be Real such that
        A17: 0 < sk
           & for x1,x2 be Real
             st x1 in dom (u|A) & x2 in dom (u|A) & |. x1-x2 .| < sk
             holds |.(u|A).x1-(u|A).x2 .| < p2v
               by A2,A15,FCONT_2:def 1,XREAL_1:215;
        consider m be Nat such that
        A18: for i be Nat st m <= i holds |. (delta T).i - 0 .| < sk
              by A4,A17,SEQ_2:def 7;
        take m;
        let n be Nat;
        A19: n in NAT & m in NAT by ORDINAL1:def 12;
        assume n >= m; then
        |. (delta T).n - 0 .| < sk & |. (delta T).m - 0 .| < sk by A18; then
        |. delta(T.n) .| < sk & |. delta(T.m) .| < sk by A19,INTEGRA3:def 2;
        then
        A20: delta(T.n) < sk & delta(T.m) < sk by ABSVALUE:def 1,INTEGRA3:9;
A21:    (middle_sum(S)).n = Sum(S.n)
           & (middle_sum(S)).m = Sum(S.m)
            by INTEGR22:def 7;
        consider p1 be FinSequence of REAL such that
        A22: p1 = Fn.n & len p1 = len (T.n)
           & for i be Nat st i in dom (T.n)
             holds
               p1.i in dom (u|divset(T.n,i))
             & ex z be Real st z = (u|divset(T.n,i)).(p1.i)
             & (S.n).i = z * (vol (divset(T.n,i),rho)) by A11,A19;
        consider p2 be FinSequence of REAL such that
        A23: p2 = Fm.m & len p2 = len (T.m)
            & for i be Nat st i in dom (T.m) holds
                p2.i in dom (u|divset(T.m,i))
              & ex z be Real st z = (u|divset(T.m,i)).(p2.i)
              & (S.m).i = z * (vol (divset(T.m,i),rho)) by A12,A19;
        defpred H1[object,object,object] means
        ex i,j being Nat, z be Real
        st $1=i & $2=j & z = (u|divset(T.n,i)).(p1.i)
         & $3 = (vol (divset(T.n,i) /\ divset(T.m,j),rho))* z;
        A24: for x,y be object st x in Seg len(T.n) & y in Seg len (T.m)
             ex w be object st w in REAL & H1[x,y,w]
        proof
          let x,y be object;
          assume
          A25: x in Seg len (T.n) & y in Seg len (T.m); then
          reconsider i=x,j=y as Nat;
          i in dom (T.n) by A25,FINSEQ_1:def 3; then
          consider z be Real such that
          A26: z = (u|divset(T.n,i)).(p1.i)
            & (S.n).i = z * (vol (divset(T.n,i),rho)) by A22;
          (vol (divset(T.n,i) /\ divset(T.m,j),rho)) * z in REAL
            by XREAL_0:def 1;
          hence thesis by A26;
        end;
        consider Snm being Function of [: Seg len (T.n),Seg len (T.m) :],REAL
        such that
        A27: for x,y be object st x in Seg len(T.n) & y in Seg len(T.m)
             holds H1[x,y,Snm.(x,y)] from BINOP_1:sch 1(A24);
        A28: for i,j being Nat st i in Seg len (T.n) & j in Seg len (T.m)
        holds
        ex z be Real
        st z = (u|divset(T.n,i)).(p1.i)
         & Snm.(i,j) = (vol (divset(T.n,i) /\ divset(T.m,j),rho))* z
        proof
          let i,j being Nat;
          assume i in Seg len (T.n) & j in Seg len (T.m); then
          ex i1,j1 being Nat, z be Real
          st i=i1 & j=j1 & z = (u|divset(T.n,i1)).(p1.i1)
           & Snm.(i,j)= (vol (divset(T.n,i1) /\ divset(T.m,j1),rho))* z by A27;
          hence thesis;
        end;
        defpred P1[Nat,object] means
        ex r be FinSequence of REAL
        st dom r = Seg len (T.m) & $2=Sum r
         & for j be Nat st j in dom r holds r.j = Snm.($1,j);
        A29: for k be Nat st k in Seg len (T.n) ex x be object st P1[k,x]
        proof
          let k be Nat;
          assume
          A30: k in Seg len (T.n);
          deffunc G(set) = Snm.(k,$1);
          consider r being FinSequence such that
          A31: len r = len (T.m) and
          A32: for j be Nat st j in dom r holds r.j = G(j) from FINSEQ_1:sch 2;
          A33: dom r = Seg len (T.m) by A31,FINSEQ_1:def 3;
          for j be Nat st j in dom r holds r.j in REAL
          proof
            let j be Nat;
            assume
            A34: j in dom r; then
            [k,j] in [: Seg len (T.n), Seg len (T.m) :]
              by A30,A33,ZFMISC_1:87; then
            Snm.(k,j) in REAL by FUNCT_2:5;
            hence thesis by A32,A34;
          end; then reconsider r as FinSequence of REAL by FINSEQ_2:12;
          take x = Sum r;
          thus thesis by A32,A33;
        end;
        consider Xp be FinSequence such that
        A35: dom Xp = Seg len (T.n)
           & for k be Nat st k in Seg len (T.n) holds P1[k,Xp.k]
            from FINSEQ_1:sch 1(A29);
        for i be Nat st i in dom Xp holds Xp.i in REAL
        proof
          let i be Nat;
          assume i in dom Xp; then
          ex r be FinSequence of REAL
          st dom r = Seg len (T.m) & Xp.i = Sum r
           & for j be Nat st j in dom r holds r.j=Snm.(i,j) by A35;
          hence thesis by XREAL_0:def 1;
        end; then
        reconsider Xp as FinSequence of REAL by FINSEQ_2:12;
        A36: len Xp = len (T.n) by A35,FINSEQ_1:def 3;
        for k be Nat st 1 <= k & k <= len Xp holds Xp.k = (S.n).k
        proof
          let k be Nat;
          assume 1 <= k & k <= len Xp; then
          A38: k in Seg len Xp & k in Seg len (T.n) by A36; then
          A39: k in dom Xp & k in dom (T.n) by FINSEQ_1:def 3; then
          consider z be Real such that
          A40: z = (u|divset(T.n,k)).(p1.k)
             & (S.n).k = z * (vol (divset(T.n,k),rho)) by A22;
          consider r be FinSequence of REAL such that
          A41: dom r = Seg len (T.m) & Xp.k = Sum r
             & for j be Nat st j in dom r holds r.j=Snm.(k,j) by A35,A38;
          defpred P11[Nat,set] means
          $2 = vol (divset(T.n,k) /\ divset(T.m,$1),rho);
          A42: for i be Nat st i in Seg len r holds
               ex x be Element of REAL st P11[i,x]
          proof
            let i be Nat;
            assume i in Seg len r;
            vol(divset(T.n,k) /\ divset(T.m,i), rho) in REAL by XREAL_0:def 1;
            hence thesis;
          end;
          consider vtntm be FinSequence of REAL such that
          A43: dom vtntm = Seg len r
             & for i be Nat st i in Seg len r
               holds P11[i,vtntm.i] from FINSEQ_1:sch 5(A42);
          A44: dom vtntm = dom r
             & for j be Nat st j in dom vtntm holds
                vtntm.j=vol (divset(T.n,k) /\ divset(T.m,j),rho)
                  by A43,FINSEQ_1:def 3;
          A45: len vtntm = len r & len (T.m) = len r
                by A41,A43,FINSEQ_1:def 3; then
          A46: Sum vtntm = vol(divset((T.n),k),rho)
                by A39,A43,INTEGR22:1,INTEGRA1:8;
          for j be Nat st j in dom r holds
          ex x be Real st x = vtntm.j & r.j = x * z
          proof
            let j be Nat;
            assume
            A47: j in dom r; then
            A48: ex w be Real
                 st w = (u|divset(T.n,k)).(p1.k)
                  & Snm.(k,j) = (vol(divset(T.n,k) /\ divset(T.m,j),rho)) * w
                    by A28,A38,A41;
            take vtntm.j;
            r.j = (vol(divset(T.n,k) /\ divset(T.m,j),rho)) * z
                  by A40,A41,A47,A48;
            hence thesis by A44,A47;
          end;
          hence thesis by A40,A41,A45,A46,Th1;
        end; then
        A49: Xp = S.n by A1,A36,INTEGR22:def 5;
        defpred P2[Nat,object] means
        ex s be FinSequence of REAL
        st dom s = Seg len (T.n) & $2 = Sum s
         & for i be Nat st i in dom s holds s.i = Snm.(i,$1);
        A50: for k be Nat st k in Seg len (T.m)
             ex x be object st P2[k,x]
        proof
          let k be Nat;
          assume
          A51: k in Seg len (T.m);
          deffunc G(set)= Snm.($1,k);
          consider s being FinSequence such that
          A52: len s = len (T.n) and
          A53: for i be Nat st i in dom s holds s.i = G(i) from FINSEQ_1:sch 2;
          A54: dom s = Seg len (T.n) by A52,FINSEQ_1:def 3;
          for i be Nat st i in dom s holds s.i in REAL
          proof
            let i be Nat;
            assume
            A55: i in dom s; then
            [i,k] in [: Seg len (T.n), Seg len (T.m) :]
                by A51,A54,ZFMISC_1:87; then
            Snm.(i,k) in REAL by FUNCT_2:5;
            hence thesis by A53,A55;
          end; then
          reconsider s as FinSequence of REAL by FINSEQ_2:12;
          take x = Sum s;
          thus thesis by A53,A54;
        end;
        consider Xq be FinSequence such that
        A56: dom Xq = Seg len (T.m)
           & for k be Nat st k in Seg len (T.m) holds P2[k,Xq.k]
                from FINSEQ_1:sch 1(A50);
        for j be Nat st j in dom Xq holds Xq.j in REAL
        proof
          let j be Nat;
          assume j in dom Xq; then
          ex s be FinSequence of REAL
          st dom s = Seg len(T.n) & Xq.j = Sum s
           & for i be Nat st i in dom s holds s.i = Snm.(i,j) by A56;
          hence thesis by XREAL_0:def 1;
        end; then
        reconsider Xq as FinSequence of REAL by FINSEQ_2:12;
        defpred H2[object,object,object] means
        ex i,j being Nat, z be Real
        st $1 = i & $2 = j & z = (u|divset(T.m,j)).(p2.j)
         & $3 = (vol((divset(T.n,i) /\ divset(T.m,j)),rho)) * z;
        A57: for x,y be object st x in Seg len (T.n) & y in Seg len (T.m)
             ex w be object st w in REAL & H2[x,y,w]
        proof
          let x,y be object;
          assume
          A58: x in Seg len (T.n) & y in Seg len (T.m); then
          reconsider i=x,j=y as Nat;
          j in dom (T.m) by A58,FINSEQ_1:def 3; then
          consider z be Real such that
          A59: z = (u|divset(T.m,j)).(p2.j)
            & (S.m).j = z * (vol (divset(T.m,j),rho)) by A23;
          (vol(divset(T.n,i) /\ divset(T.m,j),rho)) * z in REAL
            by XREAL_0:def 1;
          hence thesis by A59;
        end;
        consider Smn being Function of [: Seg len (T.n),Seg len (T.m) :], REAL
        such that
        A60: for x,y be object st x in Seg len(T.n) & y in Seg len(T.m)
             holds H2[x,y,Smn.(x,y)] from BINOP_1:sch 1(A57);
        A61: for i,j being Nat st i in Seg len(T.n) & j in Seg len(T.m) holds
             ex z be Real st z = (u|divset(T.m,j)).(p2.j)
              & Smn.(i,j) = (vol(divset(T.n,i) /\ divset(T.m,j),rho)) * z
        proof
          let i,j being Nat;
          assume i in Seg len (T.n) & j in Seg len (T.m); then
          ex i1,j1 being Nat, z be Real
          st i = i1 & j = j1 & z = (u|divset(T.m,j1)).(p2.j1)
           & Smn.(i,j) = (vol(divset(T.n,i1) /\ divset(T.m,j1),rho)) * z
              by A60;
          hence thesis;
        end;
        defpred P3[Nat,object] means
        ex s be FinSequence of REAL
        st dom s = Seg len(T.n) & $2 = Sum s
         & for i be Nat st i in dom s holds s.i = Smn.(i,$1);
        A62: for k be Nat st k in Seg len(T.m) ex x be object st P3[k,x]
        proof
          let k be Nat;
          assume
          A63: k in Seg len(T.m);
          deffunc G(set)= Smn.($1,k);
          consider s being FinSequence such that
          A64: len s = len (T.n) and
          A65: for i be Nat st i in dom s holds s.i = G(i) from FINSEQ_1:sch 2;
          A66: dom s = Seg len (T.n) by A64,FINSEQ_1:def 3;
          for i be Nat st i in dom s holds s.i in REAL
          proof
            let i be Nat;
            assume
            A67: i in dom s; then
            [i,k] in [: Seg len (T.n), Seg len (T.m) :]
                   by A63,A66,ZFMISC_1:87; then
            Smn.(i,k) in REAL by FUNCT_2:5;
            hence thesis by A65,A67;
          end; then
          reconsider s as FinSequence of REAL by FINSEQ_2:12;
          take x = Sum s;
          thus thesis by A65,A66;
        end;
        consider Zq be FinSequence such that
        A68: dom Zq = Seg len (T.m)
           & for k be Nat st k in Seg len (T.m) holds P3[k,Zq.k]
              from FINSEQ_1:sch 1(A62);
        for j be Nat st j in dom Zq holds Zq.j in REAL
        proof
          let j be Nat;
          assume j in dom Zq; then
          ex s be FinSequence of REAL
          st dom s = Seg len (T.n) & Zq.j=Sum s
           & for i be Nat st i in dom s holds s.i = Smn.(i,j) by A68;
          hence thesis by XREAL_0:def 1;
        end; then
        reconsider Zq as FinSequence of REAL by FINSEQ_2:12;
        A69: len Zq = len(T.m) by A68,FINSEQ_1:def 3;
        for k be Nat st 1 <= k & k <= len Zq holds Zq.k = (S.m).k
        proof
          let k be Nat;
          assume
          A71: 1 <= k <= len Zq; then
          consider s be FinSequence of REAL such that
          A72: dom s = Seg len(T.n) & Zq.k = Sum s
             & for i be Nat st i in dom s holds s.i = Smn.(i,k)
                by A68,FINSEQ_3:25;
          A73: k in Seg len(T.m) by A69,A71;
          A74: k in dom (T.m) by A69,A71,FINSEQ_3:25; then
          consider z be Real such that
          A75: z = (u|divset((T.m),k)).(p2.k)
            & (S.m).k = z * (vol(divset((T.m),k),rho)) by A23;
          defpred P11[Nat,set] means
          $2 = vol(divset(T.n,$1) /\ divset(T.m,k),rho);
          A76: for i be Nat st i in Seg len s holds
               ex x be Element of REAL st P11[i,x]
          proof
            let i be Nat;
            assume i in Seg len s;
            vol(divset(T.n,i) /\ divset(T.m,k),rho) in REAL by XREAL_0:def 1;
            hence thesis;
          end;
          consider vtntm be FinSequence of REAL such that
          A77: dom vtntm = Seg len s
             & for i be Nat st i in Seg len s
               holds P11[i,vtntm.i] from FINSEQ_1:sch 5(A76);
          A78: dom vtntm = dom s & len vtntm = len s by A77,FINSEQ_1:def 3;
          A79: for j be Nat st j in dom vtntm holds
               vtntm.j = vol(divset(T.m,k) /\ divset(T.n,j),rho) by A77;

          len s = len (T.n) by A72,FINSEQ_1:def 3; then
          A80: Sum vtntm = vol (divset(T.m,k),rho)
                  by A74,A78,A79,INTEGR22:1,INTEGRA1:8;

          for j be Nat st j in dom s holds
          ex x be Real st x = vtntm.j & s.j = x * z
          proof
            let j be Nat;
            assume
            A81: j in dom s; then
            A82: ex w be Real
                 st w = (u|divset((T.m),k)).(p2.k)
                  & Smn.(j,k) = (vol(divset(T.n,j) /\ divset(T.m,k),rho)) * w
                      by A61,A72,A73;
            take vtntm.j;
            s.j = (vol(divset(T.n,j) /\ divset(T.m,k),rho))* z
                    by A72,A75,A81,A82;
            hence thesis by A77,A78,A81;
          end;
          hence thesis by A72,A75,A78,A80,Th1;
        end; then
        Zq = S.m by A1,A69,INTEGR22:def 5; then
        A83: Sum(S.n) - Sum(S.m) = Sum Xq - Sum Zq by A35,A49,A56,INTEGR22:2;

        set XZq = Xq - Zq;
        A84: dom XZq = dom Xq /\ dom Zq by VALUED_1:12;
        reconsider XZq = Xq - Zq as FinSequence of REAL;

        len Xq = len Zq by A56,A68,FINSEQ_3:29; then
        A86: Xq is Element of (len Xq)-tuples_on REAL
           & Zq is Element of (len Xq)-tuples_on REAL by FINSEQ_2:92;

        A87: for i,j be Nat, Snmij,Smnij be Real
             st i in Seg len (T.n) & j in Seg len (T.m)
              & Snmij = Snm.(i,j)
              & Smnij = Smn.(i,j)
             holds
              |. Snmij - Smnij .|
              <= |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .| * pv
        proof
          let i,j be Nat, Snmij,Smnij be Real;
          assume
          A88: i in Seg len (T.n) & j in Seg len (T.m)
             & Snmij = Snm.(i,j) & Smnij = Smn.(i,j); then
          consider z1 be Real such that
          A89: z1 = (u|divset(T.n,i)).(p1.i)
             & Snm.(i,j) = (vol(divset(T.n,i) /\ divset(T.m,j),rho)) * z1
                by A28;
          consider z2 be Real such that
          A90: z2 = (u|divset((T.m),j)).(p2.j)
             & Smn.(i,j) = (vol(divset(T.n,i) /\ divset(T.m,j),rho)) * z2
                by A61,A88;

          A91: i in dom (T.n) & j in dom (T.m) by A88,FINSEQ_1:def 3; then
          A92: p1.i in dom (u|divset(T.n,i))
             & p2.j in dom (u|divset(T.m,j)) by A22,A23; then
          p1.i in dom u /\ divset(T.n,i) & p2.j in dom u /\ divset(T.m,j)
              by RELAT_1:61; then
          A93: p1.i in dom u & p1.i in divset(T.n,i)
             & p2.j in dom u & p2.j in divset(T.m,j) by XBOOLE_0:def 4;

          A94: z1 = u.(p1.i) & z2 = u.(p2.j) by A89,A90,A92,FUNCT_1:47;

          per cases;
          suppose
            divset(T.n,i) /\ divset(T.m,j) = {}; then
            vol(divset(T.n,i) /\ divset(T.m,j),rho) = (0 qua Real)
                    by INTEGR22:def 1;
            hence |. Snmij - Smnij .|
                <= |. (vol (divset(T.n,i) /\ divset(T.m,j),rho)) .| * pv
                  by A88,A89,A90,COMPLEX1:44;
          end;
          suppose
            divset(T.n,i) /\ divset(T.m,j) <> {}; then
            consider t be object such that
            A97: t in divset(T.n,i) /\ divset(T.m,j) by XBOOLE_0:def 1;
            reconsider t as Real by A97;
            A98: divset(T.m,j) c= A by A91,INTEGRA1:8;
            A99: t in divset(T.n,i) & t in divset(T.m,j)
                  by A97,XBOOLE_0:def 4; then
            |. (p1.i)-t .| < sk & |. t-(p2.j) .| < sk
                  by A20,A91,A93,INTEGR20:12; then
            A100: |. u.(p1.i)-u.t .| < p2v
               & |. u.t-u.(p2.j) .| < p2v by A1,A17,A93,A98,A99;

            reconsider DMN = divset(T.n,i) /\ divset(T.m,j)
              as real-bounded Subset of REAL by XBOOLE_1:17,XXREAL_2:45;

            Snmij - Smnij
              = (vol (DMN,rho)) * (u.(p1.i) - u.t)
                + (vol (DMN,rho)) * (u.t - u.(p2.j))
                by A88,A89,A90,A94; then
            A101: |. Snmij - Smnij .|
              <= |. (vol (DMN,rho)) * (u.(p1.i) -u.t) .|
                  + |. (vol (DMN,rho)) * (u.t - u.(p2.j)) .| by COMPLEX1:56;

            A102: |. (vol (DMN,rho)) * (u.(p1.i) - u.t) .|
                = |. vol (DMN,rho) .| * |. u.(p1.i) - u.t .|
               & |. (vol (DMN,rho)) * (u.t - u.(p2.j)) .|
                = |.vol (DMN,rho).| * |. u.t - u.(p2.j) .| by COMPLEX1:65;

            0 <= |.vol (DMN,rho).| by COMPLEX1:46; then
            |. (vol(DMN,rho)) * (u.(p1.i) - u.t) .| <= |.vol(DMN,rho).| * p2v
            & |. (vol(DMN,rho)) * (u.t - u.(p2.j)) .| <= |.vol(DMN,rho).| * p2v
                          by A100,A102,XREAL_1:64; then
            |. (vol (DMN,rho)) * (u.(p1.i) - u.t) .|
              + |. (vol (DMN,rho)) * (u.t - u.(p2.j)) .|
            <= |.vol (DMN,rho).| * p2v + |.vol (DMN,rho).| * p2v by XREAL_1:7;
            hence |. Snmij - Smnij .|
               <= |. vol (divset(T.n,i) /\ divset(T.m,j),rho) .| * pv
                  by A101,XXREAL_0:2;
          end;
        end;
        consider vtntm be FinSequence of REAL such that
        A103: len vtntm = len(T.m)
           & Sum vtntm <= total_vd(rho)
           & for j be Nat st j in dom (T.m) holds
             ex p be FinSequence of REAL
             st vtntm.j = Sum p
              & len p = len (T.n)
              & for i be Nat st i in dom (T.n) holds
                p.i = |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .|
                  by A1,Th19;
        reconsider PVD = pv * vtntm as FinSequence of REAL;
        dom PVD = dom vtntm by VALUED_1:def 5; then
        dom PVD = Seg len(T.m) by A103,FINSEQ_1:def 3; then
        A104: len PVD = len (T.m) by FINSEQ_1:def 3;
        A105: for j be Nat st j in Seg len (T.m) holds
             ex pvtntm be FinSequence of REAL
             st PVD.j = Sum pvtntm
              & len (pvtntm) = len (T.n)
              & for i be Nat st i in Seg len (T.n) holds
                (pvtntm).i = pv * |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .|
        proof
          let j be Nat;
          assume j in Seg len (T.m); then
          j in dom (T.m) by FINSEQ_1:def 3; then
          consider v be FinSequence of REAL such that
          A107: vtntm.j = Sum v
             & len v = len (T.n)
             & for i be Nat st i in dom (T.n) holds
               v.i = |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .| by A103;
          reconsider pvtntm = pv * v as FinSequence of REAL;
          take pvtntm;
          thus PVD.j = pv * vtntm.j by VALUED_1:6
                    .= Sum pvtntm by A107,RVSUM_1:87;
          dom pvtntm = dom v by VALUED_1:def 5; then
          dom pvtntm = Seg len(T.n) by A107,FINSEQ_1:def 3;
          hence len pvtntm = len(T.n) by FINSEQ_1:def 3;
          let i be Nat;
          assume i in Seg len (T.n); then
          a108: i in dom (T.n) by FINSEQ_1:def 3;
          thus (pvtntm).i = pv * v.i by VALUED_1:6
                         .= pv * |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .|
                              by A107,a108;
        end;
        A109: Sum(PVD) = pv * Sum(vtntm) by RVSUM_1:87;
        A110: pv * Sum(vtntm) <= pv * total_vd(rho)
          by A13,B13,A103,XREAL_1:64;
        A111: len XZq = len (T.m) by A56,A68,A84,FINSEQ_1:def 3;
        for j be Nat st j in dom XZq holds |. XZq.j .| <= PVD.j
        proof
          let j be Nat;
          assume
          A112: j in dom XZq; then
          A113: XZq.j = Xq.j - Zq.j by VALUED_1:13;
          consider Xsq be FinSequence of REAL such that
          A114: dom Xsq = Seg len (T.n) & Xq.j = Sum Xsq
              & for i be Nat st i in dom Xsq holds Xsq.i = Snm.(i,j)
                  by A56,A68,A84,A112;
          consider Zsq be FinSequence of REAL such that
          A115: dom Zsq = Seg len (T.n) & Zq.j = Sum Zsq
              & for i be Nat st i in dom Zsq holds
                Zsq.i = Smn.(i,j) by A56,A68,A84,A112;
          set XZsq = Xsq - Zsq;
          A116: dom XZsq = dom Xsq /\ dom Zsq by VALUED_1:12;
          reconsider XZsq as FinSequence of REAL;
          A117: len XZsq = len (T.n) by A114,A115,A116,FINSEQ_1:def 3;
          consider pvtntm be FinSequence of REAL such that
          A118: PVD.j = Sum pvtntm
              & len (pvtntm) = len (T.n)
              & for i be Nat st i in Seg len (T.n) holds
                (pvtntm).i = pv * |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .|
                  by A105,A56,A68,A84,A112;
          for i be Nat st i in dom XZsq holds |. XZsq.i .| <= (pvtntm).i
          proof
            let i be Nat;
            assume
            A119: i in dom XZsq; then
            A120: XZsq.i = Xsq.i - Zsq.i by VALUED_1:13;
            A121: (pvtntm).i
                = pv * |. vol(divset(T.n,i) /\ divset(T.m,j),rho) .|
                  by A118,A114,A115,A116,A119;
            Xsq.i = Snm.(i,j) & Zsq.i = Smn.(i,j)
                by A114,A115,A116,A119;
            hence |.XZsq.i.| <= pvtntm.i
              by A56,A68,A84,A87,A112,A114,A115,A116,A119,A120,A121;
          end; then
          A122: |. Sum XZsq .| <= PVD.j by A117,A118,Th3;
          len Xsq = len Zsq by A114,A115,FINSEQ_3:29; then
          Xsq is Element of (len Xsq)-tuples_on REAL
          & Zsq is Element of (len Xsq)-tuples_on REAL by FINSEQ_2:92;
          hence thesis by A113,A114,A115,A122,RVSUM_1:90;
        end; then
        |. Sum XZq .| <= Sum PVD by A104,A111,Th3; then
        A124: |. Sum XZq .| <= TVD * pv by A109,A110,XXREAL_0:2;
        Sum (XZq) = ((middle_sum(S)).n) - ((middle_sum(S)).m)
                    by A21,A83,A86,RVSUM_1:90;
        hence |.((middle_sum(S)).n) - ((middle_sum(S)).m).| < p
                                by A16,A124,XXREAL_0:2;
      end;
      hence middle_sum(S) is convergent by SEQ_4:41;
    end;
  end;
